
ProcessHub

  Description


Library for building distributed systems that are scalable. It handles the distribution of
processes within a cluster of nodes while providing a globally synchronized process registry.
ProcessHub takes care of starting, stopping and monitoring processes in the cluster.
It scales automatically when cluster is updated and handles network partitions.
ProcessHub provides different configuration options to define whether it operates in a
decentralized or leader-based architecture. The default distribution strategy is
decentralized and based on consistent hashing, where each node in the cluster is considered
equal. Alternatively, you can configure ProcessHub to use a centralized load balancer
strategy that relies on a leader node to make distribution decisions based on real-time
cluster metrics.
ProcessHub is eventually consistent
ProcessHub is built with scalability and availability in mind. 
Most of the operations are asynchronous and non-blocking. It can guarantee eventual consistency.
The system may not be in a consistent state at all times, 
but it will eventually converge to a consistent state.


  
    
  
  Features


Main features include:
	Automatically or manually distribute processes within a cluster of nodes.
	Distributed and synchronized process registry for fast process lookups.
	Process monitoring and automatic restart on failures (Supervisor).
	Process state handover on process migration.
	Provides different strategies out of the box to handle: 	Process migrations.
	Process distribution.
	Process synchronization.
	Process replication.
	Cluster partitioning.


	Hooks for triggering events on specific actions and extend the functionality.
	Automatic hub cluster forming and healing when nodes join or leave the cluster.
	Customizable and extendable to alter the default behavior of the system by implementing custom hook handlers and strategies.
	Optional disk-backed (DETS) registry that survives coordinator restart on a single node — opt in via :registry_backend. See Persistence.


  
    
  
  Installation


	Add process_hub to your list of dependencies in mix.exs:
 def deps do
   [
     {:process_hub, "~> 0.8.0"}
   ]
 end

	Run mix deps.get to fetch the dependencies.    

	Add ProcessHub to your application's supervision tree:
 defmodule MyApp.Application do
   use Application

   def start(_type, _args) do
     children = [
       ProcessHub.child_spec(%ProcessHub{hub_id: :my_hub})
     ]

     opts = [strategy: :one_for_one, name: MyApp.Supervisor]
     Supervisor.start_link(children, opts)
   end
 end


  It is possible to start multiple hubs under the same supervision tree, each
  with a unique :hub_id.
  By doing so, each hub will have its own cluster of processes. 
  All hubs will be independent of each other.
  For example we can start two separate hubs with different configurations.

  
    
  
  Dynamic process creation


Dynamically create 2 distributed processes under the hub :my_hub. These processes are
started asynchronously by default and are monitored by the hub.
iex> ProcessHub.start_children(:my_hub, [
  %{id: "process1", start: {MyProcess, :start_link, [nil]}},
  %{id: "process2", start: {MyProcess, :start_link, [nil]}}
])
{:ok, :start_initiated}

  
    
  
  Static process creation


Start the hub with 2 child specs. The hub will start the processes when it boots up.
child_specs = [
  %{
    id: "my_process_1",
    start: {MyProcess, :start_link, [nil]}
  },
  %{
    id: "my_process_2",
    start: {MyProcess, :start_link, [nil]}
  }
]

# Start under the supervision tree.
ProcessHub.child_spec(%ProcessHub{
  hub_id: :my_hub,
  child_specs: child_specs
})

  
    
  
  Process lookup


Query the whole registry for all processes under the hub :my_hub:
iex> ProcessHub.process_list(:my_hub, :global)
[
  {"my_process_1", [node_two@host: #PID<23772.233.0>]},
  {"my_process_2", [node_one@user: #PID<0.250.0>]}
]
Query processes by child_id:
iex> ProcessHub.child_lookup(:my_hub, "my_process_1")
{
  %{id: "my_process_1", start: {MyProcess, :start_link, [nil]}},
  [node_two@host: #PID<0.228.0>]
}
Find pid of a process by child_id:
iex> ProcessHub.get_pid(:my_hub, "my_process_1")
#PID<0.228.0>

  
    
  
  Configuration


ProcessHub runs with sensible defaults — %ProcessHub{hub_id: :my_hub} is a
complete, valid configuration. Behaviour is customized through the
%ProcessHub{} struct (see ProcessHub.t/0), which lets you swap the
distribution, migration, synchronization, replication and partition-tolerance
strategies and optionally make the process registry disk-backed.
ProcessHub.child_spec(%ProcessHub{
  hub_id: :my_hub,
  # Migrate process state to the target node during redistribution.
  migration_strategy: %ProcessHub.Strategy.Migration.HotSwap{},
  # Run each process on 2 nodes for redundancy.
  redundancy_strategy: %ProcessHub.Strategy.Redundancy.Replication{replication_factor: 2},
  # Stay available only while a quorum of nodes is connected.
  partition_tolerance_strategy: %ProcessHub.Strategy.PartitionTolerance.StaticQuorum{quorum_size: 2},
  # Persist the registry to disk so a single-node restart keeps its children.
  registry_backend: {:dets, path: "priv/my_hub.dets"}
})
See guides/Configuration.md for the configurable
strategies, ProcessHub.t/0 for the full set of hub options, and
guides/Persistence.md for the optional disk-backed
registry and the experimental declared-children recovery (:auto_recovery
with durable: true starts and an optional off-cluster remote manifest).

  
    
  
  Getting started 📚


New to ProcessHub? Start with the Getting started guide — it walks you through installation, configuration, and your first distributed processes.
Browse the full documentation for all guides and the API reference.

  
    
  
  Contributing


Contributions are welcome and appreciated. If you have any ideas, suggestions, or bugs to report,
please open an issue or a pull request on GitHub.

  
    
  
  License


Copyright 2023 Anuar Alfetahe. Licensed under the Apache License, Version 2.0.


  

    
Getting started
    

In this guide we will go through the basic usage of ProcessHub and how to integrate 
it in your application.
To get more familiar with the public API of ProcessHub, please refer to the ProcessHub module.

  
    
  
  Installation


In order to use ProcessHub in your application, you need to add it as a dependency.
Once you have added it as a dependency, you need to start the ProcessHub master supervisor.
It is highly recommended to start the ProcessHub supervisor under your application 
supervision tree.
	Add process_hub to your list of dependencies in mix.exs:
 def deps do
     [
         {:process_hub, "~> 0.8.0"}
     ]
 end

	Pull the dependency:
 mix deps.get


	Start the ProcessHub supervisor under your application supervision tree:
 defmodule MyApp.Application do
     use Application

     def start(_type, _args) do
         children = [
             ProcessHub.child_spec(%ProcessHub{hub_id: :my_hub})
         ]

         opts = [strategy: :one_for_one, name: MyApp.Supervisor]
         Supervisor.start_link(children, opts)
     end
 end


Hub ID
Each node in the cluster that starts a ProcessHub instance and shares the same :hub_id will 
form a hub cluster.
It is possible to start multiple hubs under the same supervision tree with
different configuration options, in this case, each hub must have a unique :hub_id.


  
    
  
  Example usage


The following example shows how to start 2 elixir nodes, connect them and start processes
under the ProcessHub cluster. This demonstrates how the processes are distributed in the cluster.
Note: The examples below assume that the ProcessHub is already started under the
supervision tree. If not please refer to the Installation section.
Note: Make sure you have a GenServer module called MyProcess defined in your project.
defmodule MyProcess do
    use GenServer

    def start_link(_) do
        GenServer.start_link(__MODULE__, nil)
    end

    def init(_) do
        {:ok, nil}
    end
end

  
    
  
  Node 1


Start the first node with the following command:
iex --name node1@127.0.0.1 --cookie mycookie -S mix

# Run the following in the iex console to start 5 processes under the hub.
iex> ProcessHub.start_children(:my_hub, [
...>    %{id: :process1, start: {MyProcess, :start_link, [nil]}},
...>    %{id: :process2, start: {MyProcess, :start_link, [nil]}},
...>    %{id: :process3, start: {MyProcess, :start_link, [nil]}},
...>    %{id: :process4, start: {MyProcess, :start_link, [nil]}},
...>    %{id: :process5, start: {MyProcess, :start_link, [nil]}}
...> ])
{:ok, :start_initiated}

# Check the started processes by running the command below.
iex> ProcessHub.process_list(:my_hub, :global)
[
  process1: ["node1@127.0.0.1": #PID<0.256.0>],
  process2: ["node1@127.0.0.1": #PID<0.257.0>],
  process3: ["node1@127.0.0.1": #PID<0.258.0>],
  process4: ["node1@127.0.0.1": #PID<0.259.0>],
  process5: ["node1@127.0.0.1": #PID<0.260.0>]
]

  
    
  
  Node 2


We will use this node to connect to the first node and see how the processes are
automatically distributed.
Start the second node.
iex --name node2@127.0.0.1 --cookie mycookie -S mix

# Connect the second node to the first node.
iex> Node.connect(:"node1@127.0.0.1")
true

# Check the started procsses by running the command below and
# see how some of the processes are distributed to the second node.
iex> ProcessHub.process_list(:my_hub, :global)
[
  process4: ["node2@127.0.0.1": #PID<0.285.0>],
  process3: ["node2@127.0.0.1": #PID<0.284.0>],
  process1: ["node2@127.0.0.1": #PID<0.283.0>],
  process2: ["node1@127.0.0.1": #PID<23045.257.0>],
  process5: ["node1@127.0.0.1": #PID<23045.260.0>]
]


  

    
ProcessRegistry
    

The ProcessRegistry is a global registry that keeps track of all the processes in the system. 
It is used to look up a process by its name, and to register a process with a name.
It's recommended to interact with ProcessRegistry through the main ProcessHub API module.
By default ProcessRegistry is using pubs/subs mechanism to notify subscribers about changes in the registry. This implementation can be replaced with ProcessHub.Strategy.Synchronization.Gossip or
custom implementation.
ProcessRegistry can also be used to store metadata about the processes, such as tags or other information. 
This can be useful to group processes, query them by tags or distribute data among them and trigger any custom logic.
The metadata is synchronized across the cluster, so all nodes will have the same information about the processes.
We will skip the boiler plate code for starting the child processes and focus on the registry itself.

  
    
  
  Querying the whole registry


We will start of by querying the whole registry with ProcessHub.process_list/2 function.
This function allows us to query the whole registry or a specific hub and specify if we want to include remote processes or not.
If we choose to exclude remote processes, the node names wont be included in the returned list.
We can switch between :global and :local mode by passing the second argument to the function.
The ProcessHub.process_list/2function is the most efficient way to query the whole registry because
the data is coming from the local registry and no network calls are made.
iex> ProcessHub.process_list(:my_hub, :global)
[
  my_process_1: [two@anuar: #PID<23772.233.0>],
  my_process_2: [one@anuar: #PID<0.250.0>],
  my_process_3: [one@anuar: #PID<0.253.0>],
  my_process_4: [one@anuar: #PID<0.256.0>],
  my_process_5: [one@anuar: #PID<0.259.0>],
  my_process_6: [one@anuar: #PID<0.262.0>],
  my_process_7: [one@anuar: #PID<0.265.0>],
  my_process_8: [two@anuar: #PID<23772.254.0>],
  my_process_9: [one@anuar: #PID<0.271.0>],
  my_process_10: [one@anuar: #PID<0.274.0>]
]

iex> ProcessHub.process_list(:my_hub, :local)
[
  my_process_2: #PID<0.250.0>,
  my_process_3: #PID<0.253.0>,
  my_process_4: #PID<0.256.0>,
  my_process_5: #PID<0.259.0>,
  my_process_6: #PID<0.262.0>,
  my_process_7: #PID<0.265.0>,
  my_process_9: #PID<0.271.0>,
  my_process_10: #PID<0.274.0>
]
Another similar option is ProcessHub.registry_dump/1 which dumps the whole registry into a map
including metadata stored in the registry.
iex> ProcessHub.registry_dump(:my_hub)
%{
  my_process_1: {%{id: :my_process_1, start: {MyProcess, :start_link, [nil]}},
   [two@anuar: #PID<23772.233.0>], %{tag: "Some tag"}},
  my_process_2: {%{id: :my_process_2, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.250.0>], %{custom_data: "Some data"}},
  my_process_3: {%{id: :my_process_3, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.253.0>], %{}},
  my_process_4: {%{id: :my_process_4, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.256.0>], %{}},
  my_process_5: {%{id: :my_process_5, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.259.0>], %{}},
  my_process_6: {%{id: :my_process_6, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.262.0>], %{}},
  my_process_7: {%{id: :my_process_7, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.265.0>], %{}},
  my_process_8: {%{id: :my_process_8, start: {MyProcess, :start_link, [nil]}},
   [two@anuar: #PID<23772.254.0>], %{}},
  my_process_9: {%{id: :my_process_9, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.271.0>], %{}},
  my_process_10: {%{id: :my_process_10, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.274.0>], %{}}
}
There's also a third option ProcessHub.which_children/2, which is deprecated and highly
discouraged to use.
This function does network calls to all nodes in the cluster to get the list of processes and
also may lead to memory and performance issues when used with large nuber of processes.
It's using the Supervisor.which_children/1 function under the hood which has stated in the 
documentation: Note that calling this function when supervising a large number of children
  under low memory conditions can cause an out of memory exception.
Here is an example of how to use ProcessHub.which_children/2 function:
iex> ProcessHub.which_children(:my_hub, [:global])
[
  one@anuar: [
    {:my_process_10, #PID<0.274.0>, :worker, [MyProcess]},
    {:my_process_9, #PID<0.271.0>, :worker, [MyProcess]},
    {:my_process_7, #PID<0.265.0>, :worker, [MyProcess]},
    {:my_process_6, #PID<0.262.0>, :worker, [MyProcess]},
    {:my_process_5, #PID<0.259.0>, :worker, [MyProcess]},
    {:my_process_4, #PID<0.256.0>, :worker, [MyProcess]},
    {:my_process_3, #PID<0.253.0>, :worker, [MyProcess]},
    {:my_process_2, #PID<0.250.0>, :worker, [MyProcess]}
  ],
  two@anuar: [
    {:my_process_8, #PID<23772.254.0>, :worker, [MyProcess]},
    {:my_process_1, #PID<23772.233.0>, :worker, [MyProcess]}
  ]
]

iex> ProcessHub.which_children(:my_hub, [:local])
{:one@anuar,
 [
   {:my_process_10, #PID<0.274.0>, :worker, [MyProcess]},
   {:my_process_9, #PID<0.271.0>, :worker, [MyProcess]},
   {:my_process_7, #PID<0.265.0>, :worker, [MyProcess]},
   {:my_process_6, #PID<0.262.0>, :worker, [MyProcess]},
   {:my_process_5, #PID<0.259.0>, :worker, [MyProcess]},
   {:my_process_4, #PID<0.256.0>, :worker, [MyProcess]},
   {:my_process_3, #PID<0.253.0>, :worker, [MyProcess]},
   {:my_process_2, #PID<0.250.0>, :worker, [MyProcess]}
 ]}

  
    
  
  Querying a specific child


To quickly get the PID of the running process by it's child_id we can use the
ProcessHub.get_pid/2 function which returns the process identifier.
iex> ProcessHub.get_pid(:my_hub, :my_process_10)
#PID<0.228.0>
Now when utilizing replication strategies we should default to another function ProcessHub.get_pids/2
which returns a list of PIDs for the given child_id.
iex> ProcessHub.get_pids(:my_hub, :my_process_10)
[#PID<0.228.0>]
We may also query the whole child info by using the ProcessHub.child_lookup/2 function.
This function also gives us the child_spec.
iex> ProcessHub.child_lookup(:my_hub, :my_process_10)
{
    %{id: :my_process_10, start: {MyProcess, :start_link, [nil]}},
    [one@anuar: #PID<0.228.0>]
}

  
    
  
  Process metadata


We can store metadata in the registry by starting the process with :metadata option.
# First we need to start the process with metadata
iex> ProcessHub.start_child(
  :my_hub, 
  %{id: :my_process_1, start: {MyProcess, :start_link, [nil]}}, 
  [metadata: %{some_info: "my data"}, awaitable: true]
) |> ProcessHub.Future.await()
%ProcessHub.StartResult{
  status: :ok,
  started: [my_process_1: ["node1@127.0.0.1": #PID<0.293.0>]],
  errors: [],
  rollback: false
}

# Now we can query the process with metadata
iex> ProcessHub.child_lookup(:my_hub, :my_process_1, [with_metadata: true])
{
  %{id: :my_process_1, start: {MyProcess, :start_link, [nil]}},
  [one@anuar: #PID<0.228.0>],
  %{some_info: "my data"}
}
We can also get all the metadata stored for all the processes in the registry by using
ProcessHub.registry_dump/1 function.
iex> ProcessHub.registry_dump(:my_hub)
%{
  my_process_1: {%{id: :my_process_1, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.228.0>], %{some_info: "my data"}},
  my_process_2: {%{id: :my_process_2, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.250.0>], %{}},
  my_process_3: {%{id: :my_process_3, start: {MyProcess, :start_link, [nil]}},
   [one@anuar: #PID<0.253.0>], %{}}
}
ProcessHub is also internally using :metadata to tag processes which is then used
to query the processes by tags.
iex> ProcessHub.tag_query(:my_hub, "MY_TAG")
[
  my_process_1: [one@anuar: #PID<0.228.0>],
  my_process_2: [one@anuar: #PID<0.250.0>]
]

  
    
  
  Per-child metadata


When starting multiple children at once using start_children/3, you can specify different
metadata for each child using the :child_metadata option. This is particularly useful when
you need to categorize or tag different processes individually.
iex> child_specs = [
  %{id: :worker1, start: {MyWorker, :start_link, [1]}},
  %{id: :worker2, start: {MyWorker, :start_link, [2]}},
  %{id: :worker3, start: {MyWorker, :start_link, [3]}}
]

iex> child_metadata = %{
  :worker1 => %{tag: "critical"},
  :worker2 => %{tag: "standard"},
  :worker3 => %{tag: "batch"}
}

iex> ProcessHub.start_children(
  :my_hub,
  child_specs,
  [child_metadata: child_metadata, awaitable: true]
) |> ProcessHub.Future.await()

# Now each worker has its own specific tag
iex> ProcessHub.tag_query(:my_hub, "critical")
[{:worker1, ["node1@127.0.0.1": #PID<0.293.0>]}]

iex> ProcessHub.tag_query(:my_hub, "standard")
[{:worker2, ["node1@127.0.0.1": #PID<0.294.0>]}]
You can also combine :child_metadata with the global :metadata option. When both are provided,
children specified in :child_metadata will use their specific metadata, while other children
will fall back to the global :metadata value.
iex> child_specs = [
  %{id: :priority_worker, start: {MyWorker, :start_link, [1]}},
  %{id: :regular_worker, start: {MyWorker, :start_link, [2]}}
]

iex> ProcessHub.start_children(
  :my_hub,
  child_specs,
  [
    metadata: %{tag: "default"},
    child_metadata: %{:priority_worker => %{tag: "high_priority"}},
    awaitable: true
  ]
) |> ProcessHub.Future.await()

# priority_worker gets the specific metadata
iex> ProcessHub.child_lookup(:my_hub, :priority_worker, [with_metadata: true])
{
  %{id: :priority_worker, start: {MyWorker, :start_link, [1]}},
  ["node1@127.0.0.1": #PID<0.295.0>],
  %{tag: "high_priority"}
}

# regular_worker falls back to the global metadata
iex> ProcessHub.child_lookup(:my_hub, :regular_worker, [with_metadata: true])
{
  %{id: :regular_worker, start: {MyWorker, :start_link, [2]}},
  ["node1@127.0.0.1": #PID<0.296.0>],
  %{tag: "default"}
}

  
    
  
  Persistent registries


By default the registry lives in an in-memory ETS table and is rebuilt
from peers on coordinator restart via the synchronization strategy.
For workloads that need restart-survival on a single node, ProcessHub
ships an opt-in DETS-backed registry. See Persistence
for the configuration field, file layout, recovery semantics on
corruption, and the telemetry events emitted by the backend.


  

    
Starting and stopping processes
    

The ProcessHub library provides a way to start and stop processes dynamically. 
The processes can be started under a hub and can be stopped at any time.
ProcessHub can be used with any process as long as it returns {:ok, pid} when started. We recommend using GenServer for the processes as it provides a lot of features out of the box.

  
    
  
  Process identification


The :id of the child specification is used to uniquely identify the process in the hub and can be used to stop the process or query its pid.
The :id has to be either an atom or a string. For systems that create lots of dynamic processes, it is recommended to use strings as :id because atoms are not garbage collected. 
The :id has to be unique within the hub. If a process with the same :id is started again, it may result in unexpected behavior unless the uniqueness is checked before starting the process using the :check_existing option.

  
    
  
  Starting processes


Processes can be started dynamically using the ProcessHub.start_children/3 or ProcessHub.start_child/3 functions.
The latter is a convenience function to start a single process and wraps the former.
Some examples of starting processes are:

  
    
  
  Starting multiple processes


iex> ProcessHub.start_children(:my_hub, [
  %{id: "process1", start: {MyProcess, :start_link, [nil]}},
  %{id: "process2", start: {MyProcess, :start_link, [nil]}}
])
{:ok, :start_initiated}

  
    
  
  Starting a single process


child_spec = %{id: "process_id", start: {MyProcess, :start_link, [nil]}}
ProcessHub.start_child(:my_hub, child_spec)
{:ok, :start_initiated}

  
    
  
  Starting processes statically


Processes can also be started statically under the supervision tree. This is useful when the processes are known at compile time.
defmodule MyApp.Application do
  use Application

  def start(_type, _args) do
    child_specs = [
        %{
            id: :my_process_1,
            start: {MyProcess, :start_link, [nil]}
        },
        %{
            id: :my_process_2,
            start: {MyProcess, :start_link, [nil]}
        }
    ]

    children = [
      ProcessHub.child_spec(%ProcessHub{
        hub_id: :my_hub,
        child_specs: child_specs
      })
    ]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end
end
See ProcessHub.init_opts/0 for more information on the options that can be passed to the start functions.

  
    
  
  Stopping processes


Processes can be stopped dynamically using the ProcessHub.stop_child/3 or ProcessHub.stop_children/3 functions.
Some examples of stopping processes are:
ProcessHub.stop_child(:my_hub, "child_id")
{:ok, :stop_initiated}
ProcessHub.stop_children(:my_hub, ["child_id1", "child_id2"])
{:ok, :stop_initiated}
See ProcessHub.stop_opts/0 for more information on the options that can be passed to the stop functions.

  
    
  
  Self-stopping processes


Processes can also stop themselves by sending exit signals to the linked processes (supervisor).
This is useful when the process has to stop itself based on some condition.
For processes to be eligible for self-stopping, they have to be started with a :restart option set to :transient.
If the :restart option is anything other than :transient and the stop code is not either shutdown or normal, the supervisor will try to restart the process when it stops.
This will also update the registry accordingly for all the nodes in the cluster. Keep in mind that the operation is asynchronous.

  
    
  
  Example self-stopping GenServer process


child_spec1 = %{
      id: :self_shutdown_1,
      start: {Test.Helper.TestServer, :start_link, [%{name: :self_shutdown_1}]},
      restart: :transient # Set the restart option to transient
    }

ProcessHub.start_child(:my_hub, child_spec)

# In the process module
defmodule MyProcess do
  use GenServer

  def start_link(_) do
    GenServer.start_link(__MODULE__, nil)
  end

  def init(_) do
    {:ok, nil}
  end

  def handle_info(msg, state) do
    {:stop, :normal, state} # Return the stop tuple
  end
end

  
    
  
  Asynchronous operations


All process starting and stopping operations are asynchronous by default and can be made synchronous by passing the awaitable: true option. 
By doing so, the operation returns {:ok, %ProcessHub.Future{}} which can be awaited.

  
    
  
  Example of starting a process and awaiting the result


child_spec = %{
  id: "my_process_1",
  start: {MyProcess, :start_link, [nil]}
}
ProcessHub.start_children(:my_hub, [child_spec], awaitable: true) 
|> ProcessHub.Future.await()
%ProcessHub.StartResult{
  status: :ok,
  started: [{"my_process_1", ["node1@127.0.0.1": #PID<0.231.0>]}],
  errors: [],
  rollback: false
}

  
    
  
  Example of stopping a process and awaiting the result


ProcessHub.stop_child(:my_hub, "my_process_1", awaitable: true)
|> ProcessHub.Future.await()
%ProcessHub.StopResult{
  status: :ok,
  stopped: [{"my_process_1", [:"node1@127.0.0.1"]}],
  errors: []
}

  
    
  
  When nodes disagree on where a child belongs


A node that receives a start or stop for a child it does not hold passes the request on to the node it thinks holds it, and the result names the node that started or stopped the child. If every node the child belongs to has already passed it on, the child is reported in errors as {child_id, :forward_loop}, and nothing is started or stopped for it:
%ProcessHub.StartResult{status: :error, started: [], errors: [{"my_process_1", :forward_loop}]}
A node that receives a start for a child it can place on no node at all, its distribution strategy naming none, refuses it at once with {child_id, :no_target_nodes} rather than leaving the caller to wait out its timeout.
A child the hub is migrating between nodes is never refused either way, since it no longer runs where it came from: a hub member that finds it looping starts it, and a node that is draining passes it on.

  
    
  
  Formatting and extracting information from the results


When using awaitable operations, ProcessHub returns ProcessHub.StartResult and ProcessHub.StopResult structs that contain detailed information about the operation. These structs provide both formatting functions and convenient accessor functions to extract specific information.

  
    
  
  StartResult API Functions


The ProcessHub.StartResult module provides several functions to extract information from start operation results:
Basic Information Extraction
# Start processes and get the result
result = ProcessHub.start_children(:my_hub, [child_spec1, child_spec2], awaitable: true)
|> ProcessHub.Future.await()

# Check the overall status
ProcessHub.StartResult.status(result)
:ok

# Get all child IDs that were processed
ProcessHub.StartResult.cids(result)
["child1", "child2"]

# Get all errors that occurred
ProcessHub.StartResult.errors(result)
[]
Process and Node Information
# Get the first PID from the first started process
ProcessHub.StartResult.pid(result)
#PID<0.123.0>

# Get all PIDs from all started processes
ProcessHub.StartResult.pids(result)
[#PID<0.123.0>, #PID<0.124.0>]

# Get the first node from the first started process
ProcessHub.StartResult.node(result)
:"node1@127.0.0.1"

# Get all unique nodes where processes were started
ProcessHub.StartResult.nodes(result)
[:"node1@127.0.0.1", :"node2@127.0.0.1"]

# Get the first started child entry (full details)
ProcessHub.StartResult.first(result)
{"child1", [{:"node1@127.0.0.1", #PID<0.123.0>}]}

  
    
  
  StopResult API Functions


The ProcessHub.StopResult module provides similar functions for stop operation results:
# Stop processes and get the result
result = ProcessHub.stop_children(:my_hub, ["child1", "child2"], awaitable: true)
|> ProcessHub.Future.await()

# Check the overall status
ProcessHub.StopResult.status(result)
:ok

# Get all child IDs that were processed
ProcessHub.StopResult.cids(result)
["child1", "child2"]

# Get all errors that occurred
ProcessHub.StopResult.errors(result)
[]

# Get all unique nodes where processes were stopped
ProcessHub.StopResult.nodes(result)
[:"node1@127.0.0.1", :"node2@127.0.0.1"]

# Get the first stopped child entry
ProcessHub.StopResult.first(result)
{"child1", [:"node1@127.0.0.1"]}

  
    
  
  Chaining Operations


You can chain ProcessHub operations with await and result processing in a single pipeline:
# Chain start operation with immediate formatting
{:ok, started_processes} = ProcessHub.start_children(:my_hub, [child_spec1, child_spec2], awaitable: true)
|> ProcessHub.Future.await()
|> ProcessHub.StartResult.format()

# Chain start operation with status checking
:ok = ProcessHub.start_child(:my_hub, child_spec, awaitable: true)
|> ProcessHub.Future.await()
|> ProcessHub.StartResult.status()

# Chain stop operation with child ID extraction
stopped_ids = ProcessHub.stop_children(:my_hub, ["child1", "child2"], awaitable: true)
|> ProcessHub.Future.await()
|> ProcessHub.StopResult.cids()
# ["child1", "child2"]

# Chain start operation with PID extraction
pids = ProcessHub.start_children(:my_hub, [child_spec1, child_spec2], awaitable: true)
|> ProcessHub.Future.await()
|> ProcessHub.StartResult.pids()
# [#PID<0.123.0>, #PID<0.124.0>]

  
    
  
  Pattern Matching on Result Structs


Both StartResult and StopResult are regular Elixir structs that can be pattern matched directly:
# Pattern match on successful start
result = ProcessHub.start_children(:my_hub, [child_spec1, child_spec2], awaitable: true)
|> ProcessHub.Future.await()

case result do
  %ProcessHub.StartResult{status: :ok, started: started} ->
    IO.puts("Successfully started: #{inspect(started)}")
    
  %ProcessHub.StartResult{status: :error, errors: errors, started: started} ->
    IO.puts("Some failures: #{inspect(errors)}")
    IO.puts("Some successes: #{inspect(started)}")
end

  
    
  
  Format Functions


Both result types provide format/1 functions that return tuple formats:
ProcessHub.StartResult.format(result)
{:ok, [{"child1", [{:"node1@127.0.0.1", #PID<0.123.0>}]}]}

# For error cases with rollback
{:error, {[{"child1", :timeout}], [{"child2", [{:"node1@127.0.0.1", #PID<0.124.0>}]}]}, :rollback}

ProcessHub.StopResult.format(result)  
{:ok, [{"child1", [:"node1@127.0.0.1"]}]}

# For error cases
{:error, {[{"child1", {:error, :not_found}}], []}}


  

    
Configuring the hub
    


  
    
  
  Configurable strategies


ProcessHub comes with 14 different strategies that can be used to configure the hub.
All strategies are Elixir structs that implement their own base protocol.
In fact, you can define your own strategies by implementing the base protocols.
When configuring the hub, you can pass the strategies as part of the %ProcessHub{} struct.
Look at the documentation for each strategy for more information on how to configure them.
An example can be seen below.
defmodule MyApp.Application do
  use Application

  def start(_type, _args) do
    children = [process_hub()]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  defp process_hub() do
    {ProcessHub, %ProcessHub{
      hub_id: :my_hub,
      # Configure the redundancy strategy.
      redundancy_strategy: %ProcessHub.Strategy.Redundancy.Replication{
        replication_factor: 2,
        replication_model: :active_passive,
        redundancy_signal: :none
      },
      # Configure the migration strategy.
      migration_strategy: %ProcessHub.Strategy.Migration.HotSwap{
        handover: true,
        state_ttl: 30_000
      },
      # Configure the synchronization strategy.
      synchronization_strategy: %ProcessHub.Strategy.Synchronization.PubSub{
        sync_interval: 10000
      },
      # Configure the partition tolerance strategy.
      partition_tolerance_strategy: %ProcessHub.Strategy.PartitionTolerance.MajorityQuorum{
        initial_cluster_size: 1,
        track_max_size: true
      },
      # Configure the distribution strategy.
      distribution_strategy: %ProcessHub.Strategy.Distribution.ConsistentHashing{}
    }}
  end
end
Each strategy module has additional documentation on how to configure it.

  
    
  
  Redundancy Strategy


ProcessHub.Strategy.Redundancy.Base - defines the base protocol for redundancy strategies.
This strategy is used to define how many replicas of a process should be started
across the cluster. Starting multiple instances of a process across the cluster is useful
for redundancy and fault tolerance.
Available strategies are:
	ProcessHub.Strategy.Redundancy.Singularity - only 1 process per child_id without
any replicas. This is also the default strategy and contains no special configuration options.
	ProcessHub.Strategy.Redundancy.Replication - starts multiple replicas of a process
across the cluster. The number of replicas is defined by the :replication_factor
option. This strategy also supports :active_active and :active_passive modes.
Meaning we may have one active process and the rest are passive.
The mode is defined by the :replication_model option.
This information will be passed to the started process.
The default mode is :active_active, meaning all processes are equal and considered active.


  
    
  
  Migration Strategy


ProcessHub.Strategy.Migration.Base - defines the base protocol for migration strategies.
This strategy is used to define how the processes are migrated when a node joins or leaves the cluster.
Migration is the process of moving processes from one node to another.
One of the reasons why migration happens is when a node leaves the cluster.
When a node leaves the cluster, it is possible that some processes are still running on that
node, so these need to be migrated to another node. Also, when a new node joins the
cluster, other nodes may migrate some processes over to the new node.
At the moment, there are 3 migration strategies available:
	ProcessHub.Strategy.Migration.ColdSwap - migrate processes by stopping the process
on the old node before starting it on the new node. This is the default strategy.
	ProcessHub.Strategy.Migration.HotSwap - this strategy is used to migrate processes
by starting the process on the new node before stopping it on the old node.
This strategy is useful when we want to avoid any downtime. This strategy is also
useful when the process is stateful, and we want to avoid any data loss by handing over
the state from the old process to the new process. See the module for handover examples.
	ProcessHub.Strategy.Migration.Autonomous - each node independently reconciles its local
children against the distribution strategy, without any inter-node coordination or state
handover. Experimental.

Both swap strategies share the same options: :handover, :state_ttl,
:state_query_timeout and :consent_settings. The last one takes a
ProcessHub.Strategy.Migration.MigrationConsent struct, which lets a process be asked
before it is migrated.

  
    
  
  Synchronization Strategy


ProcessHub.Strategy.Synchronization.Base - defines the base protocol for synchronization
strategies which define the method that is used to synchronize the process registry.
Available strategies are:
	ProcessHub.Strategy.Synchronization.PubSub - uses a publish/subscribe model to synchronize
the process registry. Each node in the cluster will subscribe to a topic and publish any changes to the topic.
These changes could be events such as adding or removing a process from the registry.
This is the default and recommended synchronization strategy for most users.
	ProcessHub.Strategy.Synchronization.Gossip - uses a gossip protocol to synchronize the
process registry. Using this strategy is recommended when the number of nodes in the cluster
is large. The Gossip strategy selects a predefined number of nodes to gossip with and
exchange information about the process registry.
These selected nodes will choose other nodes to gossip with and so on until all nodes in the
cluster are synchronized. It has higher latency than the PubSub strategy specially when the cluster
is rather small.


  
    
  
  Partition Tolerance Strategy


ProcessHub.Strategy.PartitionTolerance.Base - defines the base protocol for partition tolerance
strategies which define the method that is used to handle network partitions.
Available strategies are:
	ProcessHub.Strategy.PartitionTolerance.Divergence - this strategy is used to handle network
partitions by diverging the cluster into multiple subclusters. Each subcluster will have its
own hub and will be considered as a separate cluster. This strategy is the default strategy.
When the network partition is healed, the subclusters will merge back into a single cluster.
	ProcessHub.Strategy.PartitionTolerance.StaticQuorum - this strategy is used to handle network
partitions by using a static quorum. The quorum size is defined by the :quorum_size option.
When a partition happens, the ProcessHub.DistributedSupervisor process will terminate
along with its children. This strategy is useful when the number of nodes in the cluster is
known and rather fixed.
	ProcessHub.Strategy.PartitionTolerance.DynamicQuorum - this strategy is used to handle
network partitions by using a dynamic quorum. The quorum size is defined by the :quorum_size
option and :threshold_time option. The system automatically over time adapts to the number of
nodes in the cluster. When a partition happens, the ProcessHub.DistributedSupervisor process
will terminate along with its children.
A node that drains or stops its hub is not counted as lost, so any number of nodes can be
scaled down that way at once. :quorum_size must be 51 to 100.
	ProcessHub.Strategy.PartitionTolerance.MajorityQuorum - deprecated, removed in v0.9.0;
use StaticQuorum or DynamicQuorum instead. This strategy provides automatic
partition tolerance that adapts to cluster size. It tracks the maximum cluster size ever seen
and requires a majority of those nodes to be present for the cluster to operate. The quorum is
calculated as floor(max_cluster_size / 2) + 1. This strategy is ideal for clusters that start
with a single node (development or initial deployment), scale up over time, and need proper
split-brain protection once established without requiring manual quorum configuration. When
intentionally downsizing your cluster, you can reset the expected cluster size using
ProcessHub.Strategy.PartitionTolerance.MajorityQuorum.reset_cluster_size/2.

Waiting out a node failure
By default a node whose connection is lost has its children started on the other nodes as
soon as the loss is confirmed (:cluster_event_debounce). A process that keeps state
locally loses what it had not handed over, even when the node is back seconds later. Set
:nodedown_grace_period (milliseconds) to keep such a node's children placed for that
long: the node stays a hub member, its registry rows stay, and nothing starts its children
elsewhere. A start placed on it fails as it would on any unreachable node. If it rejoins
within the grace, nothing moves. If it restarted, its children are gone: with
:auto_recovery the reconcile round restarts them (see the Persistence guide); without
it, the grace ends at once and they move as below, then back to the node as it rejoins.
Once the grace runs out, the children move as they would without it, and a split that
lasts longer is then handled by the partition tolerance strategy. A node that leaves
gracefully, by stopping its hub or draining, is never waited for.

  
    
  
  Distribution Strategy:


ProcessHub.Strategy.Distribution.Base - defines the base protocol for distribution
strategies which define the method to determine the node/process mapping.
ProcessHub currently supports 3 distribution strategies:
	ProcessHub.Strategy.Distribution.ConsistentHashing - uses a consistent hash ring to determine
the node/process mapping. This strategy is the default strategy and operates in a decentralized manner.
Each node is responsible for a range of hash values, and process IDs are hashed to determine their
node assignment. When the cluster topology changes, only affected processes are redistributed,
minimizing unnecessary migrations. Supports process replication and requires no configuration options.

	ProcessHub.Strategy.Distribution.Guided - uses a predefined mapping to determine the
node/process mapping. This strategy is useful when we want to control the mapping of
processes to nodes. You must explicitly specify which nodes each child process should run on
during startup. Processes are bound to their assigned nodes and do not support migration.
This is ideal for scenarios requiring specific node placement based on hardware requirements
or geographic distribution.

	ProcessHub.Strategy.Distribution.CentralizedLoadBalancer - uses a leader-based approach where
a single leader node collects performance metrics from all nodes and makes distribution decisions
based on real-time load data. The leader is determined by highest uptime and is not configurable.
Experimental
The CentralizedLoadBalancer strategy is currently experimental and may
change in future releases. Use in production at your own discretion.

Configuration options:
	:max_history_size (default: 30) - Maximum historical load scores to maintain
	:weight_decay_factor (default: 0.9) - Exponential decay factor for historical scores
	:push_interval (default: 10,000) - Metrics collection interval in milliseconds
	:nodeup_redistribution (default: false) - Process redistribution on node join (should not be changed)





  

    
Persistence
    

By default ProcessHub keeps its per-coordinator process registry in an
in-memory ETS table, rebuilt from peers on restart via the configured
synchronization strategy. A node that restarts as a sole survivor has no
record of the children it was hosting.
For restart-survival on a single node, ProcessHub supports opt-in on-disk
registry backends, configured via the :registry_backend field on
%ProcessHub{}.

  
    
  
  Backends


:registry_backend accepts:
	:ets — (default) in-memory ETS. Unchanged prior behaviour.
	{:dets, opts} — on-disk persistence via :dets.
	{:durable_ets, opts} — hybrid: ETS for reads, mirrored synchronously
to DETS for restart-survival (see Hybrid backend).
	{Module, opts} — a custom module implementing
ProcessHub.Service.Storage.Behaviour.

Both disk backends require path: String.t(); a hub configured without
one refuses to start, because ProcessHub has no directory of its own that
your application can reach. They share the same on-disk format, so a hub
can switch between them against the same path.
ProcessHub.child_spec(%ProcessHub{
  hub_id: :my_hub,
  registry_backend: {:dets, path: "/var/lib/myapp/hub.dets"}
})

  
    
  
  Operational profile


Each DETS mutation calls :dets.sync/1 before returning, so any operation
observed as :ok is durable on disk (~1–5 ms per write on local SSD, more
on slower disks). Workloads with very high registry mutation rates should
keep the default :ets backend.
DETS does not compact automatically — deleted entries leave gaps, but the
registry is bounded by child count, so this is usually negligible. Entries
with a :ttl are stored as {key, value, expire_ms} and filtered on read;
there is no background sweeper for expired rows.
On open the file is opened with repair: true. If it is still
unrecoverable, the corrupt file is rotated to
<path>.corrupt-<system_monotonic>, an error is logged, and a fresh empty
file is opened — the hub starts empty and rebuilds cluster state from peers
rather than fail-stopping.

  
    
  
  Custom backends


Implement ProcessHub.Service.Storage.Behaviour and pass
registry_backend: {MyModule, opts}. Mutating callbacks may return
{:error, reason}, so a future replicated backend (Raft, etc.) can plug
in without breaking existing call sites.

  
    
  
  Fast-restart stale-binding reaping


If a node restarts within :net_ticktime, peers never see a :nodedown
and can be left holding registry entries that point at the node's now-dead
pids (the rejoin sync only appends). This is independent of the registry
backend — the stale rows live on the peer.
Every node broadcasts a per-boot token on startup. A peer purges another
node's bindings only when that node's token changes, which distinguishes
a genuine restart (new token → reap the dead pids) from a transient network
flap (same token → keep the live bindings). This runs for all backends,
including the default :ets, and requires no :auto_recovery. Purging only
withdraws the bindings: the :auto_recovery reconcile round restarts the
children left running nowhere, and without it nothing does. The one exception
is a node held in its :nodedown_grace_period: without :auto_recovery its
restart ends the grace, so its children move as after any failure and back to
it as it rejoins.

  
    
  
  Observability


ProcessHub reports through its hook system, not telemetry. The recovery
lifecycle is observable via the recovery_state_changed hook (see below);
registry-file corruption is logged at ERROR. There are no per-mutation
events on the hot path.

  
    
  
  Declared children and orphan recovery


Experimental
The :auto_recovery lifecycle is experimental and may change. The
persistence backends above are not affected by this notice.

With :auto_recovery enabled, a hub maintains a declared list: a versioned,
durable list of the children that SHALL exist. start_child/3 with
durable: true adds the child's spec to it; a deliberate stop removes it; no
other code path writes it. Each node then periodically reconciles the cluster
toward the list:
orphans = declared children − children observed running anywhere
The remainder is started through the normal start path with
check_existing: true, and a running child whose declared entry was removed (a
stop that crashed halfway) is stopped. The same difference covers both
directions: after a whole-cluster outage the live registry is empty and every
declared child returns; after a single-node rejoin the peers already hold the
children and the difference is empty; a child stopped during the absence is
absent from the list and stays dead — list absence is the stop record, and it
never expires, so a node may be away arbitrarily long without resurrecting a
stopped child on return.
A restored child keeps the metadata of the registry row it left behind: the row
in the live registry while there is one, bound or not, and otherwise its copy in
the durable medium, which is all a restarted hub has. A child_data_alter hook
may rewrite any key; every key it leaves alone survives.

  
    
  
  The declared list


Mutations are serialized through the hub's leader node. The leader is chosen by
:elector when it is available, and is otherwise the first hub member by name;
either way every node picks the same one. The leader increments one monotonic version
per mutation and persists before acknowledging, so "which copy is newer" is a
single integer comparison and adoption replaces the whole list. The list
mutation always commits before the process action — add before start, remove
before terminate — so either half of a crashed command heals in the next round.
Every node keeps its adopted copy in a store beside the registry file, one row
per declared child plus a version row, so a mutation writes only the rows it
changes. After each write the leader announces the new version, and a peer
behind it pulls the list and adopts it. On boot a node adopts the highest
version among its local copy, its peers, and the remote manifest. The list is exactly as durable as the registry: a backend with a
:path gets a DETS-backed list beside that file, while an :ets hub keeps the
list in memory and starts from an empty one after a restart. To keep a list
across restarts without putting the registry on disk, use :remote_manifest. With
no leader reachable, durable: true starts and stops of declared children
return {:error, :no_leader}; everything else stays leader-free.
durable: true requires a :permanent restart type (the default): a
:transient or :temporary child may finish on its own node, and no other
node could distinguish "finished" from "lost".
ProcessHub.start_child(:my_hub, child_spec, durable: true)
ProcessHub.Service.DeclaredChildren.declared_children(:my_hub)
#=> %{version: 3, children: [%{id: :my_child, ...}]}

  
    
  
  Remote manifest


An optional off-cluster copy protects the list against the loss of every
cluster disk. Configure remote_manifest: {module, opts} inside
:auto_recovery with a module implementing ProcessHub.Storage.RemoteManifest
— built-in adapters are ProcessHub.Storage.RemoteManifest.LocalPath
(dependency-free; point it at storage that lives outside the cluster) and
ProcessHub.Storage.RemoteManifest.S3 (behind the optional :ex_aws_s3
dependency, using conditional writes).
The leader ships every mutation asynchronously — retried with backoff,
coalescing superseded versions — and boot fetches the remote copy before the
first reconcile round: the higher version wins, whichever side holds it. A
failing or slow adapter never affects a command; failures emit the
manifest_ship_failed hook.

  
    
  
  A missing list is never empty truth


A missing or corrupt local list while durable evidence exists (a seeded marker
beside the list file, or durable registry rows) is not read as "nothing
declared": the hub restores from the remote manifest, or parks its reconcile —
starting and stopping nothing, emitting the alarm-grade declared_parked hook
— until an operator intervenes. The explicit operator call is
ProcessHub.Service.DeclaredChildren.clear/1.
On the first boot with the feature enabled and no stored list, the hub seeds
version 1 from its durable registry rows, once — so an existing deployment's
children carry over. The stored list has a format marker; a newer marker than
the running release understands refuses to open.

  
    
  
  Row bookkeeping


Every row carries hub-owned state under the reserved metadata key
:__process_hub__: epoch, changed_by, changed_at (diagnostics only), and
durable: true for declared children.
Every write that authors a row increments epoch. Merges resolve by higher
epoch, ties by the lexicographically lower changed_by, and adopt the winner
verbatim — so every node converges on the same value in any order. The epoch is a
counter, never a wall clock: hardware without a battery-backed clock boots with a
bogus time exactly when it rejoins and merges. Caller metadata cannot set the key.
node_pids is not part of that resolution. It is a set of per-node observations,
each owned by the node it names — a payload from node N only touches the
{N, pid} entry, and a child missing from N's payload removes nothing else.
No absence observation deletes durable state.
A deliberate stop deletes the registry row (stop memory lives in the list); a
:temporary or :transient child the supervisor declines to restart gets the
same treatment. Placement churn leaves a short-lived stub (30 seconds) for the
child's new copy to register into. If nothing registers, the janitor removes a
durable child's stub (the reconcile restarts the child while it is declared)
and re-places any other child through the distribution strategy, at most five
times with a growing back-off, before it removes the stub.

  
    
  
  Rounds and states


:recovery_state is :recovering until the first round completes, then :normal
(terminal). With auto_recovery: false it is :normal from init/1.
The first round opens on evidence: once cluster_settle_ms has passed since
start and every connected peer the hub knows about has delivered its registry
data, which counts once it has been merged into the local registry. reconcile_grace_ms caps that wait — it opens the round whatever the
evidence says, so a peer that is connected but never answers cannot hold a node
in :recovering, and :normal is always reached. Later rounds follow completed
synchronisation rounds, rate-limited to one per reconcile_interval_ms. When a
node joins the hub, a round follows within a couple of seconds instead, so a
child that could not start for want of a node is not left waiting for the full
interval. A host that knows of another reason a refused start can now succeed
(its placement target gained a member, say) calls
ProcessHub.Service.Recovery.request_round/1 for the same.
Every node submits from its adopted copy of the list. Duplicates are prevented by
check_existing: true and by the ring routing concurrent submissions to the same
owner, where the supervisor rejects the second. A round also reduces a child
observed on more than one node to its ring owner's instance, and removes rows
marked durable that are undeclared and observed running nowhere (a stale
rejoining peer's leftovers).

  
    
  
  Configuration


%ProcessHub{
  hub_id: :my_hub,
  auto_recovery: [
    reconcile_grace_ms: 30_000,
    cluster_settle_ms: 2_000,
    reconcile_interval_ms: 15_000,
    remote_manifest: {ProcessHub.Storage.RemoteManifest.LocalPath, path: "/mnt/off-cluster"}
  ]
}
	:reconcile_grace_ms — the cap on the wait for the first round, not the
normal path to it. Default 30_000, range [50, 600_000]. A value below
:cluster_settle_ms wins, so a hub tuned down keeps its timing.
	:cluster_settle_ms — how long silence from the cluster counts as "this node
is alone" before the first round may open. Default 2_000, range
[0, 60_000]. Raise it when your cluster layer is slow to connect peers; set
0 when the host forms its cluster before starting its hubs.
	:reconcile_interval_ms — minimum spacing between rounds, and the per-handler
budget for the blocking pre_recovery_replay hook. Default 15_000, range
[1_000, 600_000].
	:remote_manifest — {module, opts} implementing
ProcessHub.Storage.RemoteManifest. Default nil (disabled).

A value outside these ranges refuses the hub: ProcessHub.start_link/1 returns
{:error, {:invalid_auto_recovery, reason}} before anything is opened. A value
that is not false, true or a keyword list starts the hub with recovery
disabled and logs a warning.
The superseded keys :marker_path, :replay_timeout_ms, :recovery_timeout_ms
and :stopped_row_ttl_ms are deprecated: accepted with a WARN, ignored, and
rejected in a later release. So are Recovery.prepare_recovery/1 and
prepare_recovery_cluster/1, now no-ops. See migration-guide.md.
An opted-in hub opens its backend with recovery_replay: false: restoration
flows through the reconcile, never through the backend open, so a returning
node cannot republish its stale view as fact.

  
    
  
  Hooks


	recovery_state_changed — the :recovering → :normal transition (async).
	pre_recovery_replay — once, before the first round issues any start.
Synchronous: use it to wait on prerequisite services.
	post_recovery_replay — once, after the first round completes (async).
	reconcile_round — every round, including quiet ones, with candidates,
orphans, started, skipped_pending, duplicates, stopped_undeclared,
removed_stale, elapsed_ms.
	reconcile_duplicate — emitted by the node stopping its own duplicate instance.
	declared_tiebreak — a version tie with differing content was resolved.
	declared_parked — alarm-grade: the list is lost and the reconcile is parked.
	manifest_ship_failed — a remote ship attempt failed; the shipper retries.


  
    
  
  Introspection and failure modes


Recovery.recovery_state(:my_hub)         # :recovering | :normal
Recovery.await_normal(:my_hub, 60_000)   # :ok | {:error, :timeout}
DeclaredChildren.declared_children(:my_hub)  # %{version: v, children: [...]}
await_normal/2 returns once the first round has completed. Size the timeout
above reconcile_grace_ms.
	Parked list — the round performs no starts and no stops; a lost list is
never read as "nothing declared".
	A child mid-migration — a declared child with a registered but unbound row
must be an orphan in two consecutive rounds before it is started.
	Divergence partitions — both sides mutating the list under a non-locking
partition strategy resolve on heal by version, ties deterministically to the
lowest mutating node (declared_tiebreak fires). Quorum strategies refuse the
situation outright.


  
    
  
  Hybrid backend (:durable_ets)


{:durable_ets, opts} keeps an in-memory ETS table as the source of truth
for reads and writes, mirroring every mutation synchronously to a DETS
file. On open the DETS file is replayed into ETS so reads are immediately
authoritative.
	Reads (get, exists?, foldl, match, export_all) hit ETS
only — hot-path callers pay no DETS cost.
	Writes (insert, remove, clear_all) write ETS, then DETS, then
:dets.sync/1 before returning; once :ok is observed the row is
durable. A failed DETS write rolls back the ETS write and returns
{:error, reason}.
	Crash window — a write in memory but not yet synced is lost on
restart, identical to {:dets, _}.

	Concern	:ets	{:dets, _}	{:durable_ets, _}
	Read latency	ETS	DETS (slower)	ETS
	Write latency	ETS	DETS + fsync	ETS + DETS + fsync
	Restart-survival	no	yes	yes
	RAM footprint	rows in RAM	metadata only	rows in RAM
	Disk footprint	none	rows on disk	rows on disk

Pick {:durable_ets, _} when reads dominate and restart-survival matters;
{:dets, _} when writes dominate and RAM is constrained; :ets when
neither restart-survival nor disk durability is required.


  

    
Process state handover
    

In this guide we will show a simple example of how to handover the state of a process from one node to another.
This scenario is happening automatically when the cluster has received new node event,
meaning that the new node has joined the cluster or left.
Suppose we have the following GenServer process:
defmodule MyProcess do
  use GenServer

  def start_link(state) do
    GenServer.start_link(__MODULE__, state)
  end

  def init(state) do
    {:ok, state}
  end
end
In order to handover the state of the process from one node to another, we need to do the following:

  
    
  
  1. Configure the hub


Configure the ProcessHub to use the Hotswap strategy.
defmodule MyApp.Application do
  use Application

  def start(_type, _args) do
    children = [process_hub()]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  defp process_hub() do
    {ProcessHub, %ProcessHub{
      hub_id: :my_hub,
      migration_strategy: %ProcessHub.Strategy.Migration.HotSwap{
        handover: true,
        state_ttl: 30_000,
        state_query_timeout: 5_000
      },
    }}
  end
end
Pay attention to the handover, state_ttl and state_query_timeout options. The handover option is a boolean that indicates whether the process state should be handed over to another node when the process is going to be stopped. The state_ttl option is the max time in milliseconds that a queried state is kept before it is discarded, and state_query_timeout is the max time to wait for the local process to reply with its state.
Once the state has been delivered to the new process, the handover_delivered hook is
dispatched, making it possible to react to the handover.
State TTL
The state_ttl option does not keep the old process alive. It only limits how long
the handed-over state is retained before it is dropped.


  
    
  
  2. Implement the neccessary callbacks


In order to handover the state our MyProcess have to implement the ProcessHub.Strategy.Migration.HandoverBehaviour behaviour or define the necessary callbacks.
This can be achieved by using the ProcessHub.Strategy.Migration.HotSwap module that provides the necessary callbacks and the default implementation of the prepare_handover_state/1 and alter_handover_state/2 callbacks
defmodule MyProcess do
  use GenServer
  use ProcessHub.Strategy.Migration.HotSwap # Provides the necessary callbacks
end
Users are free to implement the alter_handover_state/2 callback in order to modify the state of the process before it is handed over to another node.
defmodule MyProcess do
  use GenServer
  use ProcessHub.Strategy.Migration.HotSwap # Provides the necessary callbacks

  # This is called on the process that is going to pass the state to another
  # newly spawned process. The returned value of this function will be passed to the
  # `alter_handover_state/2` function on the process that is going to accept the new state.
  @impl true
  def prepare_handover_state(state) do
    state
  end

  # This is called on the process that is going to accept the new handover state.
  # The process must return the new state that will be used by the process.
  @impl true
  def alter_handover_state(current_state, handover_state) do
    new_value = Map.get(handover_state, :some_key)

    # Do something with the state before returning it
    new_state = Map.put(current_state, :some_key, new_value)

    # Do something else..

    # Return the new state
    new_state
  end
end

  
    
  
  3. That's it!


Now the ProcessHub will take care of the rest. When the process is going to be
redirected to another node, the state of the process will be handed over to the new process on
the new node.

  
    
  
  Handover on node leave


The hub takes care of the handover process when a node joins the cluster and processes
migrate to the new node. 
The same can be said when a node leaves the cluster, meaning that the process states on the 
leaving node will be handed over to the remaining nodes but only if the node is shut down gracefully.
This leaves the hub with the time to handover the process states to the remaining nodes.
It is advised to scale nodes down one at a time to avoid any data loss(30 second - 10 minute intervals).

  
    
  
  Messages that arrive during a handover


A handover reads the old process's state, gives it to the new process and stops the old one. With HotSwap the old process keeps running until the new one has its state; with ColdSwap it runs until it is stopped. Messages can still reach it after its state was read, and whatever it does with them is not part of the state the new process received.
To keep those messages, turn on forward_messages in the migration strategy. Your process code stays the same:
migration_strategy: %ProcessHub.Strategy.Migration.HotSwap{handover: true, forward_messages: true}
# or
migration_strategy: %ProcessHub.Strategy.Migration.ColdSwap{handover: true, forward_messages: true}
From the moment its state is read, the old process stops handling messages and keeps them instead.
	With HotSwap, it passes them on to the new process once that one has its state. It then passes on whatever else arrives until it is stopped, including what is still in its mailbox.
	With ColdSwap, it keeps them until it is stopped. They are stored with its state, and the new process gets them right after the state.

The new process handles each passed-on message as if it had been sent to it: handle_cast/2, handle_info/2, or handle_call/3 with the answer going to the original caller.
Things to know:
	Only processes that use the HotSwap or ColdSwap macro take part, as with state handover itself.
	If no new process takes over in time, the old one goes back to work after state_ttl and handles the kept messages itself, in order.
	Order: passed-on messages keep their order among themselves. They are handled after the messages already waiting in the new process, and they are not ordered against messages sent to the new process directly.
	Calls: the old process stops right after passing on its last messages, and a caller waiting on it may see that exit before the new process answers, even though the call is still handled. With ColdSwap the gap is longer, so callers usually time out. Make such calls safe to retry.
	Not passed on: the old process's own :DOWN and :EXIT notices, which are about its monitors and links, not the new process's.
	A message that reaches the old process as it exits is lost, as it is with any process that stops. Senders that keep its pid should look it up again once it is gone.
	Node shutdown: messages are passed on when a child moves while the hub keeps running. When a node shuts down and hands its states over (see above), nothing is passed on.


  
    
  
  Messages that reach both processes


For a moment, the old and the new process may each receive the same thing: two connections to one external stream, or a sender that retried a call. Only an id or sequence number per message lets the new process skip what was already applied; carry the last applied one in the handed-over state. Without ids, the overlap cannot be resolved exactly: a message may be applied twice or missed.
defmodule MyProcess do
  use GenServer
  use ProcessHub.Strategy.Migration.HotSwap

  @impl true
  def handle_info({:work, seq, item}, {items, last_seq}) when seq > last_seq,
    do: {:noreply, {[item | items], seq}}

  # Already applied, by this process or before the handover.
  def handle_info({:work, _seq, _item}, state), do: {:noreply, state}
end

  
    
  
  More info can be found in the Hotswap module


Check out the Hotswap module for more information.


  

    
Hooks
    

Hooks are used to trigger events on specific actions. Hooks can be registered by passing the
handlers to the :hooks option of the ProcessHub.t/0 configuration struct or by inserting them
dynamically using the ProcessHub.Service.HookManager module.
ProcessHub heavily uses hooks internally in the integration tests and strategy implementations.
Hooks have to be in the format of an mfa tuple. Basically, they are functions that will be called
when the hook is triggered.
It is possible to register a hook handler with a wildcard argument :_, which will be replaced with the hook data when the hook is dispatched. Note that :_ replacement only works at the top level of the args list, not inside nested structures like tuples or lists.

  
    
  
  Hook registration examples



  
    
  
  Static hook registration


Static hook registration occurs when all hook handlers are known at the time of hub initialization
using the ProcessHub.t/0 configuration struct.
Example:
# Register a hook handler for the `:pre_node_join_hook` event with a wildcard argument.
defmodule MyApp.Application do
  alias ProcessHub.Service.HookManager
  alias ProcessHub.Constant.Hook

  use Application

  def start(_type, _args) do
    children = [
      ProcessHub.child_spec(%ProcessHub{
        hub_id: :my_hub,
        hooks: %{
          Hook.pre_node_join() => [
            %HookManager{
              id: :hook_id_1,
              m: MyModule,
              f: :my_function,
              a: [:some_data, :_]
            },
            %HookManager{
              id: :hook_id_2,
              m: MyModule2,
              f: :my_function2,
              a: [:some_data]
            }
          ],
          Hook.post_node_join() => [
            %HookManager{
              id: :hook_id_3,
              m: MyModule,
              f: :my_function,
              a: [:some_data, :_]
            }
          ]
        }
      })
    ]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end
end

  
    
  
  Dynamic hook registration


Dynamic hook registration is useful when modifying hook handlers at runtime. It allows us to add new handlers or remove existing ones.
Example:
alias ProcessHub.Service.HookManager
alias ProcessHub.Constant.Hook

# Register a hook handler for the `:post_node_join_hook` event with a wildcard argument.
ProcessHub.register_hook_handlers(
  :my_hub,
  Hook.post_node_join(),
  [
    %HookManager{
      id: :hook_id_30,
      m: MyModule,
      f: :my_function,
      a: [:some_data, :_]
    }
  ]
)

  
    
  
  Hook handler examples


# The hook handler should be in the following format:
defmodule MyModule do
  def my_function(:some_data, dynamic_hook_data) do
    # Do something with the data.
  end
end

  
    
  
  Using hooks to react and handle asynchronous events


Sometimes when starting a child process, it is necessary to know when the child process has been
started and is ready to receive messages. We could use the :awaitable option with the ProcessHub.Future.await/1 but that would
block the process that is starting the child process. Instead, we can use hooks to react to the
:child_registered event asynchronously.
Example:
# Register hook handler
alias ProcessHub.Service.HookManager
alias ProcessHub.Constant.Hook
...
hub_id = :my_hub

hook_handler1 = %HookManager{
  id: :handler_id_1,
  m: MyModule,
  f: :my_first_func,
  a: [:_]
}

hook_handler2 = %HookManager{
  id: :handler_id_2,
  m: MyModule,
  f: :my_second_func,
  a: [:hub_id, :_]
}

# We're triggering the hook when child process has been registered under the process registry.
ProcessHub.register_hook_handlers(:my_hub, Hook.child_registered(), [hook_handler1, hook_handler2])
...

# The hook handlers
defmodule MyModule do
  def my_first_func(%{child_id: child_id, node_pids: node_pids}) do
    # Send message to all started child processes.
    Enum.each(node_pids, fn {_node, pid} ->
      Process.send(pid, :hello_world, [])
    end)
  end

  def my_second_func(hub_id, hook_data) do
    ...
  end
end

  
    
  
  Internally registered hook handlers


ProcessHub uses hooks internally depending on the active configuration.
These hook handlers should never be removed or modified.
The list of internally registered hook handler IDs:
	:ch_join
	:ch_leave
	:ch_shutdown
	:mhs_shutdown
	:mhs_process_startups
	:mcs_shutdown
	:mcs_process_startups
	:rr_post_start
	:rr_post_update
	:dg_pre_start_handler


  
    
  
  Hooks in custom strategy implementations


Hooks can be used in custom strategy implementations to trigger events on specific actions and
extend the functionality of the strategy.
Here's an example of ProcessHub using hooks internally in the
ProcessHub.Strategy.Distribution.ConsistentHashing strategy implementation:
alias ProcessHub.Constant.StorageKey
alias ProcessHub.Service.Storage
alias ProcessHub.Service.HookManager

# Register hook handlers to update the hash ring when node joins or leaves the cluster.
def init(strategy, hub) do
  hub_nodes = Storage.get(hub.storage.misc, StorageKey.hn())

  Storage.insert(hub.storage.misc, StorageKey.hr(), Ring.create_ring(hub_nodes))

  join_handler = %HookManager{
    id: :ch_join,
    m: ProcessHub.Strategy.Distribution.ConsistentHashing,
    f: :handle_node_join,
    a: [hub, :_],
    p: 100
  }

  leave_handler = %HookManager{
    id: :ch_leave,
    m: ProcessHub.Strategy.Distribution.ConsistentHashing,
    f: :handle_node_leave,
    a: [hub, :_],
    p: 100
  }

  shutdown_handler = %HookManager{
    id: :ch_shutdown,
    m: ProcessHub.Strategy.Distribution.ConsistentHashing,
    f: :handle_shutdown,
    a: [hub],
    p: 100
  }

  HookManager.register_handler(hub.storage.hook, Hook.pre_node_join(), join_handler)
  HookManager.register_handler(hub.storage.hook, Hook.pre_node_leave(), leave_handler)
  HookManager.register_handler(hub.storage.hook, Hook.coordinator_shutdown(), shutdown_handler)

  # The distribution protocol requires the strategy struct back.
  strategy
end


# Handler functions that will be called when the hooks are triggered.
# Hook data is now a map: %{node: node}
def handle_node_join(hub, %{node: node}) do
  hash_ring = Ring.get_ring(hub.storage.misc) |> Ring.add_node(node)

  Storage.insert(hub.storage.misc, StorageKey.hr, hash_ring)
end

def handle_node_leave(hub, %{node: node}) do
  hash_ring = Ring.get_ring(hub.storage.misc) |> Ring.remove_node(node)

  Storage.insert(hub.storage.misc, StorageKey.hr, hash_ring)
end

  
    
  
  Hook handler priority


ProcessHub by default does not guarantee the order of hook handler execution unless
the hook handler specifies a priority level. The priority level is an integer value that
determines the order of execution of the hook handlers. The higher the priority level, the
earlier the hook handler will be executed. By default all hooks have a priority level of 0.
We define the priority level of a hook handler by setting the :p field of the ProcessHub.Service.HookManager.t/0
Here an example of how to set the priority level of a hook handler to 15:
alias ProcessHub.Service.HookManager
alias ProcessHub.Constant.Hook
...
hook_handler = %HookManager{
  id: :handler_id_1,
  m: MyModule,
  f: :handle_child_start,
  a: [],
  p: 15 # here we set the priority level to 15.
}

ProcessHub.register_hook_handlers(:my_hub, Hook.pre_node_leave(), [hook_handler])

  
    
  
  Hook handler arguments


The hook handler expects arguments which is a list of values.
These values will then be passed to the hook handler function in the same order.
Some hook dispatchers will pass additional data to the hook handler function which
then can be accessed using the wildcard argument in the handler function.
These are called wildcard arguments and are represented by the :_ symbol.
All hook data is dispatched as maps for consistency.
Example:
alias ProcessHub.Service.HookManager
alias ProcessHub.Constant.Hook
...
hook_handler = %HookManager{
  id: :handler_id_1,
  m: MyModule,
  f: :handle_child_start,
  a: [:_, :some, :something_else] # here the first argument will be the wildcard argument.
}

ProcessHub.register_hook_handlers(:my_hub, Hook.pre_node_join(), hook_handler)

# Here the handler function receives the wildcard argument as the first argument.
defmodule MyModule do
  def handle_child_start(wild_card_value, :some, :something_else) do
    # Because we used the `:pre_node_join_hook` hook event the wild_card_value will be `%{node: node()}`
  end
end
You can familiarize yourself with the available hooks and their data in the last section of this guide.

  
    
  
  Listing hook handlers


You can list all registered hook handlers for a specific hook event by calling
the registered_handlers/2 function from the ProcessHub.Service.HookManager module.
Example:
iex> alias ProcessHub.Service.HookManager
iex> alias ProcessHub.Constant.Hook
iex> HookManager.registered_handlers(hub.storage.hook, Hook.child_registered())
[
  %ProcessHub.Service.HookManager{
    id: :handler_id_2,
    m: MyModule,
    f: :my_second_func,
    a: [:hub_id, :_],
    p: 0
  }
]

  
    
  
  Removing hook handlers


You can remove specific hook handlers by calling the ProcessHub.cancel_hook_handlers/3 function.
Example:
iex> alias ProcessHub.Constant.Hook
iex> ProcessHub.cancel_hook_handlers(:my_hub, Hook.child_registered(), [:handler_id_1])
:ok
It's also possible to dispatch hooks manually by calling the dispatch_hook/3 or
dispatch_hooks/2 functions from the ProcessHub.Service.HookManager module.
Although, it's not recommended to dispatch hooks manually as it can lead to unexpected behavior.

  
    
  
  Child start flow dispatch order


When children are started, hooks fire in this order:
	:pre_children_start_hook - before any children are started, and before the receiving node checks which of the request's children belong to it
	:child_data_alter_hook - for each child, to modify child data before start (alter hook)
	:post_children_start_hook - after all children are started (includes child details)
	:child_registered_hook - for each child registered in the process registry


  
    
  
  Available hooks


	Event Key	Trigger	Data
	:pre_node_join_hook	Node joins hub cluster, before handling	%{node: node()}
	:post_node_join_hook	Node joins hub cluster, after handling	%{node: node()}
	:pre_node_leave_hook	Node leaves hub cluster, before handling	%{node: node()}
	:post_node_leave_hook	Node leaves hub cluster, after handling	%{node: node()}
	:child_registered_hook	Process registered	%{child_id: child_id(), node_pids: [{node(), pid()}]}
	:child_unregistered_hook	Process unregistered	%{child_id: child_id()}
	:migration_completed_hook	Migration handler finished	%{nodes: [node()], child_specs: [child_spec()]}
	:pre_redistribution_hook	Nodes redistribution start	%{event: :node_join | :node_leave, nodes: [node()]}
	:post_redistribution_hook	Nodes redistribution end	%{event: :node_join | :node_leave, nodes: [node()]}
	:children_forwarded_hook	Children forwarded to other nodes	%{forwards: [{node(), [map()]}]}
	:pre_children_start_hook	Before child process is started	%{request: request, hub: hub}
	:post_children_start_hook	After child processes are started	%{children: [%{child_id: cid, pid: pid, result: result, nodes: [node()], child_spec: spec, metadata: map()}]}
	:pre_children_redistribution_hook	Before redistribution of children is called	%{children: list(), event: :node_leave, node: node()}
	:coordinator_shutdown_hook	Coordinator shutdown	%{reason: any()}
	:coordinator_restarted_hook	Coordinator restarted inside a running hub	%{hub_id: atom()}
	:child_pid_updated_hook	Child process restarted with new pid	%{node: node(), pid: pid()}
	:handover_delivered_hook	Handover states delivered to migrated procs	%{child_ids: [child_id()], target_node: node()}
	:scoreboard_updated_hook	Load balancer scoreboard updated	%{scoreboard: term(), node: node()}
	:migration_deferred_hook	Children parked by migration consent	%{child_ids: [child_id()]}
	:drain_completed_hook	Node drain completed	%{migrated: non_neg_integer(), forced: non_neg_integer()}
	:recovery_state_changed_hook	:recovering → :normal transition	%{hub_id: atom(), from: atom(), to: atom(), reason: atom(), measurements: map()}
	:pre_recovery_replay_hook	Before the first reconcile round's starts (synchronous)	%{hub_id: atom(), child_count: non_neg_integer()}
	:post_recovery_replay_hook	After the first reconcile round	%{hub_id: atom(), child_count: non_neg_integer(), succeeded: non_neg_integer(), failed: non_neg_integer(), reason: atom()}
	:reconcile_round_hook	End of every orphan reconcile round	%{hub_id: atom(), first_round: boolean(), measurements: map()}
	:reconcile_duplicate_hook	A double-bound child reduced to one instance	%{hub_id: atom(), child_id: term(), instance_count: pos_integer(), kept_node: node(), stopped_nodes: [node()]}


  
    
  
  Alter hooks


Alter hooks differ from the other hooks in that they are used to modify the hook data
before it is passed to the function that is using that data. This allows us to alter the data
instead of just reacting to it and cause side effects as in the regular hooks.
Registering an alter hook is exactly the same as registering a normal hook.
Alter hooks must return the modified data in the same format as the original data.
Warning
Alter hooks should be used with caution as they can lead to unexpected behavior if not used properly.
For example, if you modify the hook data in an alter hook, it will be passed to the next hook handler
and can cause unexpected behavior if the next hook handler or the code is not expecting the modified data.
Never change the underlying data structure of the hook data such as from map to list etc.


  
    
  
  List of alter hooks


	Event Key	Trigger	Data
	:child_data_alter_hook	Before supervisor starts the child process	map() including child spec, metadata and nodes; a migrated child also has migrated_from: node()

See ProcessHub.Constant.Hook module for more information on available hooks.


  

    
Manual distribution
    


  
    
  
  Introduction


By default ProcessHub uses the ProcessHub.Strategy.Distribution.ConsistentHashing strategy to distribute processes.
This is automatic and the ProcessHub will decide which node to start the process on.
This strategy is useful for most use cases, but sometimes you may want to distribute processes manually. This guide will show you how to do that.
By manually distributing processes, you can control which processes are started on which nodes. 
This can be useful when you want to distribute processes based on specific criteria, such as the node's hardware capabilities or the process's workload.
Let's dive in a see some examples.

  
    
  
  Example GenServer


As always our processes should have some template to follow. Here is a simple GenServer process that we will use in our examples:
defmodule MyProcess do
  use GenServer

  def start_link(state) do
    GenServer.start_link(__MODULE__, state)
  end

  def init(state) do
    {:ok, state}
  end
end

  
    
  
  The configuration


First, let's configure the ProcessHub to use the ProcessHub.Strategy.Distribution.Guided strategy.
defmodule MyApp.Application do
  use Application

  def start(_type, _args) do
    children = [process_hub()]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  defp process_hub() do
    {ProcessHub, %ProcessHub{
      hub_id: :my_hub,
      # We have to swap the default distribution strategy with the guided one.
      distribution_strategy: %ProcessHub.Strategy.Distribution.Guided{}
    }}
  end
end

  
    
  
  Start 2 nodes


Now let's start 2 nodes and connect them to each other.
iex --name node1@127.0.0.1 --cookie mycookie -S mix

iex --name node2@127.0.0.1 --cookie mycookie -S mix

From node 1, connect to node 2(or vice versa):
Node.connect(:"node2@127.0.0.1")

  
    
  
  Start distributed processes.


Now let's start a process on node 1 and guide it to node 2.
iex> node1_child = %{id: :node1_child, start: {MyProcess, :start_link, [nil]}}
iex> node2_child = %{id: :node2_child, start: {MyProcess, :start_link, [nil]}}
iex> ProcessHub.start_children(:my_hub, [node1_child, node2_child], [
...>    child_mapping: %{
...>        node1_child: [:"node1@127.0.0.1"],
...>        node2_child: [:"node2@127.0.0.1"],
...>    }
...> ])
In the example above, we started 2 processes, node1_child and node2_child. We also specified that node1_child should be started on node 1 and node2_child should be started on node 2.
We do this by adding the child_mapping option to the ProcessHub.start_children/3 function. The child_mapping option is a map that specifies which node to start the process on.
Each key in the map is the id of the process and the value is a list of nodes to start the process on.
Why use lists to specify the node?
The reason we use lists for the child_mapping is that we can specify multiple nodes for a 
process if we want to replicate the process on multiple nodes. 
This requires the ProcessHub.Strategy.Redundancy.Replication strategy to be used. Which we will cover in another guide.
For example: node1_child: [:"node1@127.0.0.1", :"node2@127.0.0.1"]


  
    
  
  Checking the registered processes


Now let's check the registered processes on each node.
iex> ProcessHub.process_list(:my_hub, :global)
[
  node1_child: ["node1@127.0.0.1": #PID<0.280.0>],
  node2_child: ["node2@127.0.0.1": #PID<22474.276.0>]
]
We can see that the node1_child process is registered on node 1 and the node2_child process is registered on node 2.
The child_mapping is mandatory
If we decide to use the ProcessHub.Strategy.Distribution.Guided strategy, we have to specify the child_mapping option when starting the processes. Otherwise {:error, :missing_child_mapping} will be returned when starting the processes.



  

    
Replicating processes
    

In a distributed system, it can be important to replicate processes within a cluster of nodes. This can lead to better resilience and reliability of the system.
When one node unexpectedly fails, the replicated processes on other nodes can take over the work of the failed node immediately.
In this guide, we will show a simple example of how to replicate processes and prioritize them.

  
    
  
  Prerequisites


As always we should have some process template to follow. You can re use the MyProcess GenServer from the Manual Distribution guide.

  
    
  
  The configuration


First, let's configure the ProcessHub to use the ProcessHub.Strategy.Redundancy.Replication strategy.
defmodule MyApp.Application do
  use Application

  def start(_type, _args) do
    children = [process_hub()]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  defp process_hub() do
    {ProcessHub, %ProcessHub{
      hub_id: :my_hub,
      redundancy_strategy: %ProcessHub.Strategy.Redundancy.Replication{    
        replication_factor: 2,
        replication_model: :active_passive,
        redundancy_signal: :all
      },
    }}
  end
end
Let's explain the used options:
	replication_factor: The number of replicas that will be created for each process. Meaning if the value is 2, then the process will be replicated on 2 nodes.
	replication_model: This is optional and can be either :active_passive or :active_active. The :active_passive model means that only one of the replicas will be marked as active and the others will be passive. We will get into more details about this later.
	redundancy_signal: This is optional and can be used to toggle on/off the message sent
to the replicas to notify them about their current state (:passive or :active). This all will be explained in the next sections.


  
    
  
  Start 2 nodes


Now let's start two nodes and connect them to each other. 
You can refer to the Manual Distribution guide for an example.

  
    
  
  Start child


Next let's start a process on one node and then see how it is replicated on the other node.
We will be using the awaitable just for demonstration purposes and see the results printed in the console.
iex> child_spec = %{id: :child1, start: {MyProcess, :start_link, [nil]}}
iex> ProcessHub.start_children(:my_hub, [child_spec], [awaitable: true]) 
iex> |> ProcessHub.Future.await()
iex> |> ProcessHub.StartResult.format()
{:ok,
 [
   child1: [
     "node1@127.0.0.1": #PID<0.264.0>,
     "node2@127.0.0.1": #PID<22914.996.0>
   ]
 ]}
***17:08:08.277 [error] MyProcess #PID<0.264.0> received unexpected message in handle_info/2: {:process_hub, :redundancy_signal, :passive}***
If we examine the result, we can see that the process child1 was started on both nodes, meaning it was replicated.
But what's up with the error message?
Well, the error message is expected. It is a signal sent to the process to notify it that it is either in passive or active mode. This is part of the redundancy_signal option we set in the ProcessHub configuration.
We could have used the redundancy_signal: :none option to disable the signal, but we wanted to show you how it works.
Redundancy Signal
The redundancy_signal option is used to toggle on/off the message sent to the replicas to notify them about their current state (:passive or :active). 
This message needs to be handled by the process.

Here's an example how we handle the signal in the MyProcess. In the following example, we
save the signal in the state and handle incoming messages based on the state.
# The required callback we have to implement, to handle the signal.
def handle_info({:process_hub, :redundancy_signal, mode}, state) do
    # Save the mode in the state for later use.
    {:noreply, %{mode: mode}}
end

# Below are examples of how we can handle the signal in the process.
# These are just examples and you can implement your own logic based on the mode.

# Here we define two different handle_info functions based on the mode.
# The second one handles the request because we're the active process.
# The first one does nothing because we're the passive process.

def handle_info({:handle_request, _request}, %{mode: :passive} = state) do
    # Ignore and don't do anything because we're the passive process.
    {:noreply, state}
end

def handle_info({:handle_request, request}, %{mode: :active} = state) do
    # Handle the request because we're the active process.
    handle_request(request)
    {:noreply, state}
end

  
    
  
  Conclusion


The ProcessHub.Strategy.Redundancy.Replication can be used not only for replicating processes but also to manipulate the behavior of the replicas. This can be done by using the :redundancy_signal with :replication_model options.
ProcessHub defines currently two redundancy strategies, You can check these modules for custom configuration options:
	ProcessHub.Strategy.Redundancy.Replication
	ProcessHub.Strategy.Redundancy.Singularity



  

    
Creating custom strategy
    

It's time to extend the functionality of the ProcessHub and we will do this
by creating a custom distribution strategy.

  
    
  
  Prerequisites


As always, we should have some process template to follow. You can reuse the MyProcess GenServer from the Manual Distribution guide.

  
    
  
  Implementation


Our custom distribution strategy will be very simple and probably not very
useful in practice, but it will serve as a good example of how to create one.
This distribution strategy will distribute processes by comparing the node names. We will also take advantage
of the hook system to further customize the behavior of the system.
Let's start by creating a new file called compare.ex. We can place the file anywhere
in the project as long as it is picked up by the compiler.
It is a good practice to add some custom namespacing to the module to avoid conflicts
with other modules. We will use CustomStrategy as the namespace.
defmodule CustomStrategy.Compare do
end
Our custom distribution strategy should define a struct which can contain any 
number of custom options. In our example, we will define a single option called
direction which will determine if the selected node is either the first or the last
node in the list of nodes.
We will also create our implementation of the ProcessHub.Strategy.Distribution.Base protocol.
defmodule CustomStrategy.Compare do
    alias ProcessHub.Strategy.Distribution.Base, as: DistributionStrategy

    # We can define custom options.
    defstruct [
        direction: :asc     
    ]

    defimpl DistributionStrategy, for: CustomStrategy.Compare do
    end
end
The ProcessHub.Strategy.Distribution.Base protocol defines some functions that we need to implement. The first function is the init/2 function which is called very early when
the coordinator is started. This can be a good place to register any custom hook handlers that we need to use. We're going to use this function to register a hook handler that will print the name of
the node that is joining the hub just to demonstrate the hook system.
...
defimpl DistributionStrategy, for: CustomStrategy.Compare do
    alias ProcessHub.Service.HookManager
    alias ProcessHub.Constant.Hook

    @impl true
    def init(strategy, %ProcessHub.Hub{} = hub) do
      handler = %HookManager{
        id: :some_id_here,
        m: CustomStrategy.Compare,
        f: :handle_node_join,
        a: [hub, :_]
      }

      HookManager.register_handler(hub.storage.hook, Hook.pre_node_join(), handler)

      # The protocol requires the strategy struct back - it is stored as the
      # hub's distribution strategy.
      strategy
    end
end
...
Let's also define the handler function! The pre_node_join hook data is a map,
so we pattern match the node out of it.
defmodule CustomStrategy.Compare do
...
    def handle_node_join(hub, %{node: node}) do
        IO.puts("Node #{node} is joining the hub #{hub.hub_id}")
    end
end
...
At this point we have 4 more functions to implement. Let's continue by
overriding the children_init/4 function which does nothing but return :ok.
If we return anything else other than :ok, the startup will fail for this
particular function.
...
@impl true
def children_init(_struct, _hub, _child_specs, _opts), do: :ok
...
Next is the belongs_to/4 function. This function will determine the node that the process should be distributed to. In our case, we will select a node based on its name.
The very same function will also be used when processes are redistributed.
It receives a list of child ids and returns a map of child_id to a list of nodes.
We return a list of nodes although we only select one. The reason for this is that the function can return multiple nodes in case the process should be replicated.
For the sake of simplicity, we will ignore the replication factor in this example.
...
@impl true
def belongs_to(struct, %ProcessHub.Hub{} = hub, child_ids, _replication_factor) do
    hub_nodes = ProcessHub.Service.Cluster.nodes(hub.storage.misc, [:include_local])

    selected_node = case struct.direction do
        :asc -> Enum.sort(hub_nodes) |> Enum.at(0)
        :desc -> Enum.sort(hub_nodes) |> Enum.reverse() |> Enum.at(0)
    end

    # Ignore the replication factor and just return one node
    Map.new(child_ids, fn child_id -> {child_id, [selected_node]} end)
end
...
The last two functions tell ProcessHub whether the distribution depends only on the
node topology. Our strategy does, so it is deterministic and its signature is derived
from the sorted node list.
...
@impl true
def deterministic?(_struct), do: true

@impl true
def distribution_signature(_struct, %ProcessHub.Hub{} = hub) do
    ProcessHub.Service.Cluster.nodes(hub.storage.misc, [:include_local])
    |> Enum.sort()
    |> :erlang.phash2()
end
...
This is it!

  
    
  
  Final implementation


Our final implementation of the CustomStrategy.Compare module should look like this:
defmodule CustomStrategy.Compare do
  alias ProcessHub.Strategy.Distribution.Base, as: DistributionStrategy

  # We can define custom options.
  defstruct [
    direction: :asc
  ]

  def handle_node_join(%ProcessHub.Hub{} = hub, %{node: node}) do
      IO.puts("Node #{node} is joining the hub #{hub.hub_id}")
  end

  defimpl DistributionStrategy, for: CustomStrategy.Compare do
    alias ProcessHub.Service.HookManager
    alias ProcessHub.Constant.Hook

    @impl true
    def init(strategy, %ProcessHub.Hub{} = hub) do
      handler = %HookManager{
        id: :some_id_here,
        m: CustomStrategy.Compare,
        f: :handle_node_join,
        a: [hub, :_]
      }

      HookManager.register_handler(hub.storage.hook, Hook.pre_node_join(), handler)

      strategy
    end

    @impl true
    def children_init(_struct, _hub, _child_specs, _opts), do: :ok

    @impl true
    def belongs_to(struct, %ProcessHub.Hub{} = hub, child_ids, _replication_factor) do
        hub_nodes = ProcessHub.Service.Cluster.nodes(hub.storage.misc, [:include_local])

        selected_node = case struct.direction do
          :asc -> Enum.sort(hub_nodes) |> Enum.at(0)
          :desc -> Enum.sort(hub_nodes) |> Enum.reverse() |> Enum.at(0)
        end

        # Ignore the replication factor and just return one node
        Map.new(child_ids, fn child_id -> {child_id, [selected_node]} end)
    end

    @impl true
    def deterministic?(_struct), do: true

    @impl true
    def distribution_signature(_struct, %ProcessHub.Hub{} = hub) do
        ProcessHub.Service.Cluster.nodes(hub.storage.misc, [:include_local])
        |> Enum.sort()
        |> :erlang.phash2()
    end
  end
end

  
    
  
  Switching to the custom strategy


Replace the default distribution strategy with our custom strategy in the ProcessHub configuration.
defmodule MyApp.Application do
  use Application

  @impl true
  def start(_type, _args) do
    children = [process_hub()]

    opts = [strategy: :one_for_one, name: MyApp.Supervisor]
    Supervisor.start_link(children, opts)
  end

  defp process_hub() do
    {ProcessHub, %ProcessHub{
      hub_id: :my_hub,
      distribution_strategy: %CustomStrategy.Compare{
        direction: :desc
      }
    }}
  end
end


  
    
  
  Test drive


Let's start two nodes on separate terminals.
iex --name node1@127.0.0.1 --cookie mycookie -S mix

iex --name node2@127.0.0.1 --cookie mycookie -S mix

Connect the nodes by running the following command on the node1 terminal.
iex> Node.connect(:"node2@127.0.0.1")
true
Time to see the magic happen!
iex> ProcessHub.start_children(:my_hub, [
...>    %{id: "process1", start: {MyProcess, :start_link, [nil]}},
...>    %{id: "process2", start: {MyProcess, :start_link, [nil]}},
...>    %{id: "process3", start: {MyProcess, :start_link, [nil]}},
...>    %{id: "process4", start: {MyProcess, :start_link, [nil]}},
...>    %{id: "process5", start: {MyProcess, :start_link, [nil]}}
...> ])
{:ok, :start_initiated}
iex> ProcessHub.process_list(:my_hub, :global)
[
  {"process1", ["node2@127.0.0.1": #PID<23391.238.0>]},
  {"process2", ["node2@127.0.0.1": #PID<23391.239.0>]},
  {"process3", ["node2@127.0.0.1": #PID<23391.240.0>]},
  {"process4", ["node2@127.0.0.1": #PID<23391.241.0>]},
  {"process5", ["node2@127.0.0.1": #PID<23391.242.0>]}
]
We can confirm that all processes are started on the second node when we
pass the :desc option to the struct.

  Overview


The overall architecture of ProcessHub is designed to provide a reliable and resilient
distributed system that can handle network partitions, node failures, process migrations,
This is mostly achieved by asynchronous and non-blocking operations, and by using the
Supervisor behavior to monitor and restart processes when they die unexpectedly.
ProcessHub is eventually consistent meaning that it can guarantee that the state of the
system will eventually converge to a consistent state. This enables the system to be
scalable and highly available. 
ProcessHub internally uses a event-driven communication and ability to define listeners/hooks.
This enables some type of way to react to specific events such as process registration etc.
Most of the operations are carried out using special Task processes. These processes are
started on demand by the ProcessHub.Coordinator process and are supervised by the Task.Supervisor.
The coordinator process is responsible for coordinating the operations and making sure that
the operations are carried out in the correct order. This process is the heart of the system and
is responsible for the overall functionality of the system.

  
    
  
  Supervision tree


[image: supervision_tree]

  
    
  
  Processes


	coordinator - The coordinator process is responsible for coordinating the operations and making sure that the operations are carried out in the correct order. This process is the heart of the system and is responsible for the overall functionality of the system. 
All actions are dispatched to the coordinator process who then delegates the work to the correct handler process.

	distributed_supervisor - The distributed supervisor process is responsible for starting, stopping, and monitoring the processes in its local cluster. It uses the Supervisor behavior to monitor the processes and restart them when they die unexpectedly.

	event_queue_sup (external library) - The event queue supervisor starts and supervises the event queue  processes. The event queue is used to dispatch events within the Erlang distribution system to all nodes in the cluster. This provides a way to communicate between nodes and synchronize the operations in the system.
These processes are started by external library blockade.

	janitor - The janitor process is responsible for cleaning up the system and removing any stale data. It periodically checks the system for any stale data and removes it to keep the system clean and efficient. A child whose last copy a move stopped and that no node registered within 30 seconds is not dropped: the janitor starts it again where the distribution strategy places it, a bounded number of times.

	task_supervisor - The task supervisor process is responsible for supervising the task processes that are started on demand by the coordinator process. These processes are used to carry out the operations in the system and are supervised by the task supervisor process.

	worker_queue - The worker queue process is used to synchronize the operations that may introduce race conditions.

	bootstrap_worker - The bootstrap worker performs the hub's startup work, such as starting the statically configured child_specs.

	process_registry - The process registry process owns the registry storage and serializes writes to it.



  
    
  
  Cluster Discovery and Formation


ProcessHub monitors connecting and disconnecting nodes and forms a cluster automatically
from the connected nodes that share the same hub_id. It's not required to start
the ProcessHub on all nodes in the cluster.

  
    
  
  Resilience and Reliability


ProcessHub uses the Supervisor behavior and leverages the features that come with it.
Each hub starts its own ProcessHub.DistributedSupervisor process, which is responsible for
starting, stopping, and monitoring the processes in its local cluster.
When a process dies unexpectedly, the ProcessHub.DistributedSupervisor will restart it
automatically.
ProcessHub also takes care of validating the child_spec before starting it and makes sure
it's started on the right node that the process belongs to.
If the process is being started on the wrong node, the initialization request will be forwarded
to the correct node.

  
    
  
  Work Serialization


ProcessHub utilizes the :blockade library to provide event-driven communication.
Operations that must not interleave are delegated to the worker queue
(ProcessHub.Worker.WorkerQueue), which runs them one at a time in the order they were
received. This preserves data integrity without blocking the coordinator itself. A job
that fails is logged as an error and costs only itself: the queue moves on to the next one.
The coordinator never waits on slow work itself. Merging a joining node's registry runs
in the worker queue, and waiting on another node or on a remote manifest store runs in a
task. The parts of a hub fixed when it starts (its id, processes, storage and recovery
settings) are held in ProcessHub.Hub, so any process reads them with
ProcessHub.Hub.get/1 instead of asking the coordinator.
ProcessHub.is_locked?/1 reports whether the coordinator has delegated work that has
not completed yet. It is informational only and does not block event processing.

                                 Apache License
                           Version 2.0, January 2004
                        http://www.apache.org/licenses/

   TERMS AND CONDITIONS FOR USE, REPRODUCTION, AND DISTRIBUTION

   1. Definitions.

      "License" shall mean the terms and conditions for use, reproduction,
      and distribution as defined by Sections 1 through 9 of this document.

      "Licensor" shall mean the copyright owner or entity authorized by
      the copyright owner that is granting the License.

      "Legal Entity" shall mean the union of the acting entity and all
      other entities that control, are controlled by, or are under common
      control with that entity. For the purposes of this definition,
      "control" means (i) the power, direct or indirect, to cause the
      direction or management of such entity, whether by contract or
      otherwise, or (ii) ownership of fifty percent (50%) or more of the
      outstanding shares, or (iii) beneficial ownership of such entity.

      "You" (or "Your") shall mean an individual or Legal Entity
      exercising permissions granted by this License.

      "Source" form shall mean the preferred form for making modifications,
      including but not limited to software source code, documentation
      source, and configuration files.

      "Object" form shall mean any form resulting from mechanical
      transformation or translation of a Source form, including but
      not limited to compiled object code, generated documentation,
      and conversions to other media types.

      "Work" shall mean the work of authorship, whether in Source or
      Object form, made available under the License, as indicated by a
      copyright notice that is included in or attached to the work
      (an example is provided in the Appendix below).

      "Derivative Works" shall mean any work, whether in Source or Object
      form, that is based on (or derived from) the Work and for which the
      editorial revisions, annotations, elaborations, or other modifications
      represent, as a whole, an original work of authorship. For the purposes
      of this License, Derivative Works shall not include works that remain
      separable from, or merely link (or bind by name) to the interfaces of,
      the Work and Derivative Works thereof.

      "Contribution" shall mean any work of authorship, including
      the original version of the Work and any modifications or additions
      to that Work or Derivative Works thereof, that is intentionally
      submitted to Licensor for inclusion in the Work by the copyright owner
      or by an individual or Legal Entity authorized to submit on behalf of
      the copyright owner. For the purposes of this definition, "submitted"
      means any form of electronic, verbal, or written communication sent
      to the Licensor or its representatives, including but not limited to
      communication on electronic mailing lists, source code control systems,
      and issue tracking systems that are managed by, or on behalf of, the
      Licensor for the purpose of discussing and improving the Work, but
      excluding communication that is conspicuously marked or otherwise
      designated in writing by the copyright owner as "Not a Contribution."

      "Contributor" shall mean Licensor and any individual or Legal Entity
      on behalf of whom a Contribution has been received by Licensor and
      subsequently incorporated within the Work.

   2. Grant of Copyright License. Subject to the terms and conditions of
      this License, each Contributor hereby grants to You a perpetual,
      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
      copyright license to reproduce, prepare Derivative Works of,
      publicly display, publicly perform, sublicense, and distribute the
      Work and such Derivative Works in Source or Object form.

   3. Grant of Patent License. Subject to the terms and conditions of
      this License, each Contributor hereby grants to You a perpetual,
      worldwide, non-exclusive, no-charge, royalty-free, irrevocable
      (except as stated in this section) patent license to make, have made,
      use, offer to sell, sell, import, and otherwise transfer the Work,
      where such license applies only to those patent claims licensable
      by such Contributor that are necessarily infringed by their
      Contribution(s) alone or by combination of their Contribution(s)
      with the Work to which such Contribution(s) was submitted. If You
      institute patent litigation against any entity (including a
      cross-claim or counterclaim in a lawsuit) alleging that the Work
      or a Contribution incorporated within the Work constitutes direct
      or contributory patent infringement, then any patent licenses
      granted to You under this License for that Work shall terminate
      as of the date such litigation is filed.

   4. Redistribution. You may reproduce and distribute copies of the
      Work or Derivative Works thereof in any medium, with or without
      modifications, and in Source or Object form, provided that You
      meet the following conditions:

      (a) You must give any other recipients of the Work or
          Derivative Works a copy of this License; and

      (b) You must cause any modified files to carry prominent notices
          stating that You changed the files; and

      (c) You must retain, in the Source form of any Derivative Works
          that You distribute, all copyright, patent, trademark, and
          attribution notices from the Source form of the Work,
          excluding those notices that do not pertain to any part of
          the Derivative Works; and

      (d) If the Work includes a "NOTICE" text file as part of its
          distribution, then any Derivative Works that You distribute must
          include a readable copy of the attribution notices contained
          within such NOTICE file, excluding those notices that do not
          pertain to any part of the Derivative Works, in at least one
          of the following places: within a NOTICE text file distributed
          as part of the Derivative Works; within the Source form or
          documentation, if provided along with the Derivative Works; or,
          within a display generated by the Derivative Works, if and
          wherever such third-party notices normally appear. The contents
          of the NOTICE file are for informational purposes only and
          do not modify the License. You may add Your own attribution
          notices within Derivative Works that You distribute, alongside
          or as an addendum to the NOTICE text from the Work, provided
          that such additional attribution notices cannot be construed
          as modifying the License.

      You may add Your own copyright statement to Your modifications and
      may provide additional or different license terms and conditions
      for use, reproduction, or distribution of Your modifications, or
      for any such Derivative Works as a whole, provided Your use,
      reproduction, and distribution of the Work otherwise complies with
      the conditions stated in this License.

   5. Submission of Contributions. Unless You explicitly state otherwise,
      any Contribution intentionally submitted for inclusion in the Work
      by You to the Licensor shall be under the terms and conditions of
      this License, without any additional terms or conditions.
      Notwithstanding the above, nothing herein shall supersede or modify
      the terms of any separate license agreement you may have executed
      with Licensor regarding such Contributions.

   6. Trademarks. This License does not grant permission to use the trade
      names, trademarks, service marks, or product names of the Licensor,
      except as required for reasonable and customary use in describing the
      origin of the Work and reproducing the content of the NOTICE file.

   7. Disclaimer of Warranty. Unless required by applicable law or
      agreed to in writing, Licensor provides the Work (and each
      Contributor provides its Contributions) on an "AS IS" BASIS,
      WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or
      implied, including, without limitation, any warranties or conditions
      of TITLE, NON-INFRINGEMENT, MERCHANTABILITY, or FITNESS FOR A
      PARTICULAR PURPOSE. You are solely responsible for determining the
      appropriateness of using or redistributing the Work and assume any
      risks associated with Your exercise of permissions under this License.

   8. Limitation of Liability. In no event and under no legal theory,
      whether in tort (including negligence), contract, or otherwise,
      unless required by applicable law (such as deliberate and grossly
      negligent acts) or agreed to in writing, shall any Contributor be
      liable to You for damages, including any direct, indirect, special,
      incidental, or consequential damages of any character arising as a
      result of this License or out of the use or inability to use the
      Work (including but not limited to damages for loss of goodwill,
      work stoppage, computer failure or malfunction, or any and all
      other commercial damages or losses), even if such Contributor
      has been advised of the possibility of such damages.

   9. Accepting Warranty or Additional Liability. While redistributing
      the Work or Derivative Works thereof, You may choose to offer,
      and charge a fee for, acceptance of support, warranty, indemnity,
      or other liability obligations and/or rights consistent with this
      License. However, in accepting such obligations, You may act only
      on Your own behalf and on Your sole responsibility, not on behalf
      of any other Contributor, and only if You agree to indemnify,
      defend, and hold each Contributor harmless for any liability
      incurred by, or claims asserted against, such Contributor by reason
      of your accepting any such warranty or additional liability.

   END OF TERMS AND CONDITIONS

Copyright 2023 Anuar Alfetahe

Licensed under the Apache License, Version 2.0 (the "License");
you may not use this file except in compliance with the License.
You may obtain a copy of the License at

    http://www.apache.org/licenses/LICENSE-2.0

Unless required by applicable law or agreed to in writing, software
distributed under the License is distributed on an "AS IS" BASIS,
WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
See the License for the specific language governing permissions and
limitations under the License.



  

    
ProcessHub 
    



      
This is the main public API module for the ProcessHub library. It is recommended to use
only the functions defined in this module to interact with the ProcessHub library.
ProcessHub is a library that distributes processes within the BEAM cluster. It is designed to
be used as a building block for distributed applications that require process distribution
and synchronization across multiple nodes.

ProcessHub.Coordinator 
    



      
The ProcessHub coordinator module is responsible for coordinating most of the ProcessHub events and work.
In most cases, the coordinator module delegates the work to other service-based
modules or handler processes that are created on demand.
Each ProcessHub instance has its own coordinator process that handles the
coordination. These processes are supervised by the ProcessHub.Initializer
supervisor.
The coordinator stores state about the ProcessHub instance, such as the cluster nodes.
Additionally, the coordinator takes care of any periodic tasks required by the
ProcessHub instance, such as initial synchronization, propagation, etc.

ProcessHub.Coordinator.State 
    



      
The coordinator's state: the hub's fixed parts (ProcessHub.Hub) and the
bookkeeping that changes as the coordinator handles messages.

ProcessHub.DistributedSupervisor behaviour
    



      
The ProcessHub distributed supervisor module is responsible for starting and stopping
the child processes distributed across the cluster.
Each ProcessHub instance has its own distributed supervisor that manages local
child processes.

ProcessHub.Hub 
    



      
The parts of a hub that are fixed when it starts: its id, its processes, its
storage and its parsed :auto_recovery config.
A running hub is stored before any of its processes start, so any process
reads it with get/1 without messaging the coordinator. The coordinator's
changing bookkeeping lives in ProcessHub.Coordinator.State.

ProcessHub.Initializer 
    



      
The main ProcessHub initializer supervisor module.
This module is responsible for starting all the child processes of ProcessHub.

ProcessHub.Strategy.Distribution.Base protocol
    



      
The distribution strategy protocol defines behaviour to identify the nodes
which are responsible for a child process.

ProcessHub.Strategy.Distribution.CentralizedLoadBalancer 
    



      
Provides implementation for distribution behavior using centralized load balancing.
Experimental
This strategy is experimental and may change in future releases.
Use in production at your own discretion.

This strategy implements a centralized approach to process distribution where a single
leader node collects performance metrics from all nodes in the cluster and makes
distribution decisions based on real-time load data.
Unlike the ProcessHub.Strategy.Distribution.ConsistentHashing strategy that uses
deterministic hash-based distribution, the centralized load balancer actively monitors
cluster resources and dynamically assigns processes to the least loaded nodes.

  
    
  
  How It Works


The centralized load balancer operates through a leader election mechanism:
	Leader Election: Uses the :elector library to elect a single leader node.
The leader is determined by highest uptime - the node that has been running
the longest becomes the leader. This selection criteria is currently not configurable.
Elector comes along as a process_hub dependency, but it is left out when
you build a release. Add {:elector, "~> 0.3.4"} to your own dependencies,
or this strategy will stop working in a release.
	Metrics Collection: Each node periodically sends performance metrics to the leader
	Load Scoring: The leader calculates load scores based on multiple system metrics
	Distribution: New processes are assigned to nodes with the lowest load scores

The load scoring algorithm considers the following BEAM VM metrics:
	Scheduler utilization (40% weight) - CPU usage across schedulers
	Run queue length (30% weight) - Number of processes waiting to run
	Process count (20% weight) - Total number of processes on the node
	Memory usage (10% weight) - Total memory consumption


  
    
  
  Key Characteristics



  
    
  
  No Process Replication


Important Limitation
This strategy does not support process replication. Only a single instance
of each process can exist at any time across the cluster. This makes it unsuitable
for use cases requiring high availability through process redundancy.


  
    
  
  Single Hub Limitation


Configuration Constraint
When ProcessHub is used with multiple different hubs and configurations,
only one single hub can be configured to use the centralized load balancer
strategy at any given time in the cluster.


  
    
  
  No Process Shuffling


Unlike some distribution strategies, the centralized load balancer does not
shuffle existing processes when new nodes join the cluster. New processes will
be distributed to optimal nodes based on current load, but existing processes
remain where they are. However, when a node leaves the cluster, its processes
will be redistributed to other available nodes.

  
    
  
  Configuration Options


The strategy can be configured using the following struct fields:
	:max_history_size (default: 30) - Maximum number of historical load scores
to maintain for each node. Used for calculating weighted averages and trend analysis.

	:weight_decay_factor (default: 0.9) - Exponential decay factor applied to
historical scores. Values closer to 1.0 give more weight to historical data,
while values closer to 0.0 prioritize recent measurements.

	:push_interval (default: 10_000) - Interval in milliseconds between
metric collection and transmission from each node to the leader.



  
    
  
  Usage Example


iex> distribution_strategy = %ProcessHub.Strategy.Distribution.CentralizedLoadBalancer{
iex>   max_history_size: 50,
iex>   weight_decay_factor: 0.8,
iex>   push_interval: 5_000
iex> }
iex>
iex> hub_config = %ProcessHub{
iex>   hub_id: :my_hub,
iex>   distribution_strategy: distribution_strategy
iex> }

  
    
  
  Comparison with ConsistentHashing


	Feature	CentralizedLoadBalancer	ConsistentHashing
	Distribution Basis	Real-time load metrics	Deterministic hashing
	Process Shuffling	No (on node join)	Yes (minimal)
	Replication Support	No	Yes
	Leader Dependency	Yes	No
	Production Ready	No (experimental)	Yes
	Multiple Hubs	No (single hub only)	Yes

ProcessHub.Strategy.Distribution.ConsistentHashing 
    



      
Provides implementation for distribution behaviour using consistent hashing.
This strategy uses consistent hashing to determine the nodes and child processes
mapping.
The consensus is achieved in the cluster by creating a hash ring. The hash ring
is a ring of nodes where each node is responsible for a range of hash values.
The hash value of a child process is used to determine which node is responsible
for the child process.
When the cluster is updated, the hash ring is recalculated.
The recalculation is done in a way that each node is assigned a unique
hash value, and they form a hash ring. Each node in the cluster keeps track of
the ProcessHub cluster and updates its local hash ring accordingly.
To find the node that the process belongs to, the system will use the hash ring to calculate
the hash value of the process ID (child_id) and assign it to the node with the closest hash value.
When the cluster is updated and the hash ring is recalculated, it does not mean that all
processes will be shuffled. Only the processes that are affected by the change will
be redistributed. This is done to avoid unnecessary process migrations.
For example, when a node leaves the cluster, only the processes that were running on that node
will be redistributed. The rest of the processes will stay on the same node. When a new node
joins the cluster, only some of the processes will be redistributed to the new node, and the
rest will stay on the same node.
The hash ring implementation does not guarantee that all processes will always be
evenly distributed, but it does its best to distribute them as evenly as possible.

This is the default distribution strategy.

ProcessHub.Strategy.Distribution.Guided 
    



      
Provides implementation for distribution behaviour using consistent hashing.
This strategy expects the child mappings to be provided during process
start-up initialization. The child mappings are used to determine the nodes and
processes mapping.
Bounded processes
Guided distribution strategy does not support process migration.
If a node goes down, the processes will not be migrated to other nodes.
They are bound to the nodes specified in the child mappings.

Guided distribution strategy is useful when you want to have more control over
the distribution of processes. For example, you can use it to ensure that
processes are started on specific nodes.
Required mappings
When using Guided distribution strategy, you must provide the child mappings
during the initialization. If the child mappings are not provided, the
initialization will fail.
Example:
iex> child_spec = %{id: :my_child, start: {MyProcess, :start_link, [nil]}}
iex> ProcessHub.start_children(:my_hub, [child_spec], [child_mapping: %{my_child: [:node1, :node2]}])

ProcessHub.Strategy.Migration.Autonomous 
    



      
The autonomous migration strategy implements the ProcessHub.Strategy.Migration.Base protocol.
Unlike ColdSwap and HotSwap which coordinate process migration between nodes via
start/stop requests, the Autonomous strategy takes a fundamentally different approach:
each node independently reconciles its local state against belongs_to, stopping
children that shouldn't be here and starting children that should be here.
There is no inter-node communication and no state handover.
Experimental
This strategy is experimental and may change in future releases.
Use in production at your own discretion.

ProcessHub.Strategy.Migration.Base protocol
    



      
The migration strategy protocol provides API functions for migrating child processes.

ProcessHub.Strategy.Migration.ColdSwap 
    



      
The cold swap migration strategy implements the ProcessHub.Strategy.Migration.Base protocol.
It provides a migration strategy where the local process is terminated before starting it on
the remote node.
Cold swap is a safe strategy if we want to ensure that the child process is not
running on multiple nodes at the same time.
This is the default strategy for process migration.

  
    
  
  State Handover


When handover: true is set, ColdSwap will:
	Query state from local processes before termination
	Store states in ETS with TTL
	Terminate local processes
	Send start requests to new nodes
	When new processes are registered, deliver stored state via hook

With forward_messages: true as well, messages that reach the old process after
its state was read are not lost: it keeps them, they are stored with its state
when it stops, and the new process gets them right after the state. See
"Messages that arrive during a handover" in the State Handover guide.
To use state handover, your GenServer must use ProcessHub.Strategy.Migration.ColdSwap:
defmodule MyServer do
  use GenServer
  use ProcessHub.Strategy.Migration.ColdSwap

  # Optionally override these callbacks:
  # def prepare_handover_state(state), do: state
  # def alter_handover_state(_current, handover), do: handover
end
State Handover with Replication
State handover is not supported when using the ProcessHub.Strategy.Redundancy.Replication
strategy. With replication, multiple instances of a process run across the cluster, making
state handover semantics undefined. If you attempt to use handover: true with replication,
the hub will fail to start with {:error, {:invalid_config, :handover_with_replication_not_supported}}.


  
    
  
  Migration Consent


Set consent_settings to let processes postpone their own migration.
See ProcessHub.Strategy.Migration.MigrationConsent.

ProcessHub.Strategy.Migration.HandoverBehaviour behaviour
    



      
Shared behaviour for migration state handover callbacks.
This behaviour defines the callbacks used by both HotSwap and ColdSwap
migration strategies for state handover during process migration.
Implement these callbacks to customize how state is prepared before
migration and how it's applied to the new process.

ProcessHub.Strategy.Migration.HotSwap 
    



      
The hot swap migration strategy implements the ProcessHub.Strategy.Migration.Base protocol.
It provides a migration strategy where the local process is terminated after the new one is
started on the remote node and registered.
Hot swap is useful when we want to ensure that there is no downtime when migrating
the child process to the remote node. The old process remains alive until the new process
is successfully registered, at which point the state is delivered and the old process
is terminated.
This is the key difference from ColdSwap, which terminates the local process before
starting the remote one.

  
    
  
  State Handover


When handover: true is set, HotSwap will:
	Query state from local processes before sending start requests
	Store states in ETS with TTL (along with old process reference)
	Send start requests to new nodes
	When new processes start on the target node, the post-action callback
notifies the originating node
	Originating node delivers stored state and terminates old local process

With forward_messages: true as well, messages that reach the old process after
its state was read are not lost: it keeps them, and passes them on to the new
process once that one has its state. See "Messages that arrive during a
handover" in the State Handover guide.
To use state handover, your GenServer must use ProcessHub.Strategy.Migration.HotSwap:
defmodule MyServer do
  use GenServer
  use ProcessHub.Strategy.Migration.HotSwap

  # Optionally override these callbacks:
  # def prepare_handover_state(state), do: state
  # def alter_handover_state(_current, handover), do: handover
end
State Handover with Replication
State handover is not supported when using the ProcessHub.Strategy.Redundancy.Replication
strategy. With replication, multiple instances of a process run across the cluster, making
state handover semantics undefined. If you attempt to use handover: true with replication,
the hub will fail to start with {:error, {:invalid_config, :handover_with_replication_not_supported}}.


  
    
  
  Migration Consent


Set consent_settings to let processes postpone their own migration.
See ProcessHub.Strategy.Migration.MigrationConsent.

ProcessHub.Strategy.Migration.MigrationConsent behaviour
    



      
Opt-in migration consent, enabled by setting consent_settings on the
HotSwap or ColdSwap migration strategy.
Before migrating a participating child, the hub asks the process whether it
may be moved. :ready migrates it thr